abb-agent

LOW

maintainer RyLoS 0 votes scanned 2026-10-20 21:29:05.029414

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Marco Ziliani (rylos)
    
      2pkgname=abb-agent
    
      3_pkgname=abb-agent
    
      4pkgver=0.2.0
    
      5pkgrel=1
    
      6pkgdesc="Replacement for the Synology Active Backup for Business Linux agent: any distro and kernel, first-class btrfs, bare-metal restore (https://github.com/rylos/abb-agent)"
    
      7arch=('x86_64' 'aarch64')
    
      8url="https://github.com/rylos/abb-agent"
    
      9license=('GPL-3.0-or-later')
    
      10depends=('glibc' 'libgcc')
    
      11makedepends=('cargo')
    
      12conflicts=("$_pkgname-git" "$_pkgname-bin")
    
      13backup=('etc/abb-agent.toml')
    
      14# ring compiles C code: GCC LTO objects cannot be linked by the Rust toolchain.
    
      15options=('!lto')
    
      16install=abb-agent.install
    
      17source=("$_pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
    
      18sha256sums=('0b20649496a134fcbb72fe3594627bc811b65303092a7e6518f1886deac092fa')
    
      19
    
      20prepare() {
    
      21  cd "$_pkgname-$pkgver"
    
      22  export RUSTUP_TOOLCHAIN=stable
    
      23  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
    
      24}
    
      25
    
      26build() {
    
      27  cd "$_pkgname-$pkgver"
    
      28  export RUSTUP_TOOLCHAIN=stable
    
      29  export CARGO_TARGET_DIR=target
    
      30  cargo build --frozen --release -p abb-agent -p abb-restore
    
      31}
    
      32
    
      33check() {
    
      34  cd "$_pkgname-$pkgver"
    
      35  export RUSTUP_TOOLCHAIN=stable
    
      36  cargo test --frozen --release
    
      37}
    
      38
    
      39package() {
    
      40  cd "$_pkgname-$pkgver"
    
      41  install -Dm755 target/release/abb-agent "$pkgdir/usr/bin/abb-agent"
    
      42  install -Dm755 target/release/abb-restore "$pkgdir/usr/bin/abb-restore"
    
      43  install -Dm644 packaging/systemd/abb-agent.service "$pkgdir/usr/lib/systemd/system/abb-agent.service"
    
      44  install -Dm644 packaging/systemd/abb-agent-fixup.service "$pkgdir/usr/lib/systemd/system/abb-agent-fixup.service"
    
      45  install -Dm644 packaging/abb-agent.toml "$pkgdir/etc/abb-agent.toml"
    
      46  install -Dm644 README.md "$pkgdir/usr/share/doc/$_pkgname/README.md"
    
      47  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      48}
    
      49

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-20 21:29:05	Low	1