age-plugin-fido2-hmac

LOW

maintainer oxy 0 votes scanned 2026-10-29 13:52:19.945196

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Elmar Athmer <elmar+aur at athmer dot org>
    
      2pkgname=age-plugin-fido2-hmac
    
      3pkgver=0.5.0
    
      4pkgrel=1
    
      5pkgdesc='Age plugin to encrypt files with FIDO2 tokens using the hmac-secret extension'
    
      6arch=('x86_64' 'aarch64')
    
      7url='https://github.com/olastor/age-plugin-fido2-hmac'
    
      8license=('MIT')
    
      9depends=('glibc' 'libfido2')
    
      10makedepends=('go')
    
      11optdepends=('age: age encryption tool'
    
      12            'rage: Rust implementation of age')
    
      13source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
    
      14sha256sums=('dfdc7df03f444411bd531435f604b96c133350201e90b006e437829759d39883')
    
      15
    
      16prepare() {
    
      17  cd "$pkgname-$pkgver"
    
      18  export GOFLAGS="-mod=readonly -modcacherw"
    
      19  go mod download
    
      20}
    
      21
    
      22build() {
    
      23  cd "$pkgname-$pkgver"
    
      24  export CGO_CPPFLAGS="$CPPFLAGS"
    
      25  export CGO_CFLAGS="$CFLAGS"
    
      26  export CGO_CXXFLAGS="$CXXFLAGS"
    
      27  export CGO_LDFLAGS="$LDFLAGS"
    
      28  export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
    
      29  go build \
    
      30    -ldflags "-linkmode=external -X main.Version=v$pkgver" \
    
      31    -o "$pkgname" \
    
      32    ./cmd/age-plugin-fido2-hmac
    
      33}
    
      34
    
      35check() {
    
      36  cd "$pkgname-$pkgver"
    
      37  go test ./...
    
      38}
    
      39
    
      40package() {
    
      41  cd "$pkgname-$pkgver"
    
      42  install -Dm755 "$pkgname" -t "$pkgdir/usr/bin"
    
      43  install -Dm644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
    
      44  install -Dm644 docs/*.md -t "$pkgdir/usr/share/doc/$pkgname"
    
      45  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
    
      46}
    
      47

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-29 13:52:19	Low	1