age-plugin-openpgp-card

LOW

maintainer oxy 0 votes scanned 2026-10-29 13:52:19.945196

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Elmar Athmer <elmar+aur at athmer dot org>
    
      2pkgname=age-plugin-openpgp-card
    
      3pkgver=0.1.2
    
      4pkgrel=1
    
      5pkgdesc='Age plugin for using ed25519 on OpenPGP Card devices (YubiKeys, Nitrokeys)'
    
      6arch=('x86_64' 'aarch64')
    
      7url='https://github.com/wiktor-k/age-plugin-openpgp-card'
    
      8license=('Apache-2.0 OR MIT')
    
      9depends=('glibc' 'libgcc' 'pcsclite')
    
      10makedepends=('cargo')
    
      11optdepends=('ccid: generic USB smart card reader driver'
    
      12            'age: age encryption tool'
    
      13            'rage: Rust implementation of age')
    
      14source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
    
      15sha256sums=('ad96bf09753be937f81f58a17450bd3b50e115a511ce8d1e7eefb4557c9a54c8')
    
      16
    
      17prepare() {
    
      18  cd "$pkgname-$pkgver"
    
      19  export RUSTUP_TOOLCHAIN=stable
    
      20  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
    
      21}
    
      22
    
      23build() {
    
      24  cd "$pkgname-$pkgver"
    
      25  export RUSTUP_TOOLCHAIN=stable
    
      26  export CARGO_TARGET_DIR=target
    
      27  cargo build --frozen --release
    
      28}
    
      29
    
      30check() {
    
      31  cd "$pkgname-$pkgver"
    
      32  export RUSTUP_TOOLCHAIN=stable
    
      33  cargo test --frozen
    
      34}
    
      35
    
      36package() {
    
      37  cd "$pkgname-$pkgver"
    
      38  install -Dm755 "target/release/$pkgname" -t "$pkgdir/usr/bin"
    
      39  install -Dm644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
    
      40  install -Dm644 LICENSE-APACHE LICENSE-MIT -t "$pkgdir/usr/share/licenses/$pkgname"
    
      41}
    
      42

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-29 13:52:19	Low	1