agent-pwa-notifications

LOW

maintainer Quatro 0 votes scanned 2026-09-03 19:54:21.739188

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Xavier Francisco <echo moc.liamg@ocsicnarf.n.reivax | rev>
    
      2
    
      3pkgname=agent-pwa-notifications
    
      4pkgver=1.0.0
    
      5pkgrel=1
    
      6pkgdesc="CLI for a self-hosted Agent Notifications hub: connect an agent, mint a sign-in link, send updates and questions"
    
      7arch=('any')
    
      8url="https://github.com/Qu4tro/agent-pwa-notifications"
    
      9license=('MIT')
    
      10depends=('nodejs>=20')
    
      11makedepends=('npm')
    
      12provides=('agent-notify-pwa')
    
      13options=('!strip' '!debug')
    
      14source=("$pkgname-$pkgver.tar.gz::https://github.com/Qu4tro/agent-pwa-notifications/archive/refs/tags/v$pkgver.tar.gz")
    
      15sha256sums=('b399d4baf7d4a6f8b68db3e7caa41e1d0639936abcefd33e4486f9c1d26a263d')
    
      16
    
      17# The tarball is the whole hub repository; only cli/ is packaged. The CLI has
    
      18# one runtime dependency (qrcode-terminal) and no build step.
    
      19build() {
    
      20  cd "$pkgname-$pkgver/cli"
    
      21  npm install --omit=dev --no-audit --no-fund --no-package-lock
    
      22}
    
      23
    
      24package() {
    
      25  cd "$pkgname-$pkgver"
    
      26
    
      27  local _dest="$pkgdir/usr/lib/$pkgname"
    
      28  install -dm755 "$_dest"
    
      29  cp -r cli/bin.mjs cli/lib cli/package.json cli/node_modules "$_dest/"
    
      30
    
      31  install -dm755 "$pkgdir/usr/bin"
    
      32  ln -s "../lib/$pkgname/bin.mjs" "$pkgdir/usr/bin/agent-notify-pwa"
    
      33
    
      34  # npm leaves the build user as the owner and hands out random directory
    
      35  # permissions. See https://bugs.archlinux.org/task/63396
    
      36  chmod 755 "$_dest/bin.mjs"
    
      37  find "$_dest" -type d -exec chmod 755 {} +
    
      38  find "$_dest" -type f -perm /022 -exec chmod go-w {} +
    
      39  chown -R root:root "$pkgdir"
    
      40
    
      41  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      42  install -Dm644 cli/README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
    
      43}
    
      44

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-03 19:54:21	Low	1