alpm-dbus-client-git
LOW
maintainer ogarcia
0 votes
base
alpm-dbus-git
scanned 2026-10-07 14:05:47.471701
Why flagged
Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.
Triggered rules
Low
Few votes, recently uploaded
zero_votes_recent
Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.
PKGBUILD
1
# Maintainer: "Amhairghin" Oscar Garcia Amor (https://ogarcia.me)
2
3
pkgbase=alpm-dbus-git
4
pkgname=('alpm-dbus-git' 'alpm-dbus-client-git' 'alpm-packagekit-git')
5
pkgver=0.4.0.r48.g086356a
6
pkgrel=1
7
pkgdesc='D-Bus service for system package management on top of ALPM'
8
arch=('x86_64')
9
url='https://gitlab.archlinux.org/ogarcia/alpm-dbus'
10
license=('Apache-2.0 OR MIT')
11
# pacman and xz provide libalpm and liblzma to link against, and pacman-conf
12
# for the tests; dbus provides the dbus-daemon the tests start.
13
makedepends=('cargo' 'git' 'pacman' 'xz')
14
checkdepends=('dbus')
15
# makepkg's LTO turns the C code bundled by zstd-sys into GCC bitcode, which
16
# the Rust linker cannot link.
17
options=('!lto')
18
# The ALPM project crates are path dependencies on a checkout next to
19
# alpm-dbus (../alpm). Until upstream MR !652 is merged and released, they
20
# come from this fork branch.
21
source=('alpm-dbus::git+https://gitlab.archlinux.org/ogarcia/alpm-dbus.git'
22
'alpm::git+https://gitlab.archlinux.org/ogarcia/alpm.git#branch=feat/repo-db-access')
23
b2sums=('SKIP'
24
'SKIP')
25
26
pkgver() {
27
cd alpm-dbus
28
printf '%s.r%s.%s' "$(git describe --tags --abbrev=0)" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
29
}
30
31
prepare() {
32
cd alpm-dbus
33
export RUSTUP_TOOLCHAIN=stable
34
cargo fetch --locked --target "$(rustc --print host-tuple)"
35
}
36
37
build() {
38
cd alpm-dbus
39
export RUSTUP_TOOLCHAIN=stable
40
export CARGO_TARGET_DIR=target
41
cargo build --frozen --release \
42
--package alpm-dbus \
43
--package alpm-dbus-client --features alpm-dbus-client/cli \
44
--package alpm-packagekit
45
}
46
47
check() {
48
cd alpm-dbus
49
export RUSTUP_TOOLCHAIN=stable
50
export CARGO_TARGET_DIR=target
51
# The D-Bus tests start their own dbus-daemon, and the upgrade tests run
52
# libalpm transactions in a system inside a temporary directory.
53
cargo test --frozen --workspace --all-features
54
}
55
56
package_alpm-dbus-git() {
57
depends=('dbus' 'glibc' 'libgcc' 'libgcc_s.so' 'pacman' 'libalpm.so' 'polkit' 'xz' 'liblzma.so')
58
optdepends=('alpm-dbus-client: command line client'
59
'alpm-packagekit: PackageKit backend, for GNOME Software or KDE Discover')
60
provides=('alpm-dbus')
61
conflicts=('alpm-dbus')
62
63
cd alpm-dbus
64
install -Dm0755 -t "$pkgdir/usr/bin" target/release/alpm-dbus
65
66
install -Dm0644 -t "$pkgdir/usr/lib/systemd/system" alpm-dbus/data/alpm-dbus.service
67
install -Dm0644 -t "$pkgdir/usr/share/dbus-1/system.d" alpm-dbus/data/me.ogarcia.AlpmDbus1.conf
68
install -Dm0644 -t "$pkgdir/usr/share/dbus-1/system-services" \
69
alpm-dbus/data/me.ogarcia.AlpmDbus1.service
70
install -Dm0644 -t "$pkgdir/usr/share/polkit-1/actions" alpm-dbus/data/me.ogarcia.AlpmDbus1.policy
71
72
install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
73
install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE.Apache-2.0.txt LICENSE.MIT.txt
74
}
75
76
package_alpm-dbus-client-git() {
77
pkgdesc='Command line client of the alpm-dbus service'
78
# Not linked against, but useless without the service.
79
depends=('alpm-dbus' 'glibc' 'libgcc' 'libgcc_s.so')
80
provides=('alpm-dbus-client')
81
conflicts=('alpm-dbus-client')
82
83
cd alpm-dbus
84
install -Dm0755 -t "$pkgdir/usr/bin" target/release/alpm-dbus-client
85
install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE.Apache-2.0.txt LICENSE.MIT.txt
86
}
87
88
package_alpm-packagekit-git() {
89
pkgdesc='PackageKit backend for the alpm-dbus service'
90
# Not linked against: packagekitd provides the symbols it uses when it
91
# loads the backend, and the service does the work.
92
depends=('alpm-dbus' 'glibc' 'libgcc' 'libgcc_s.so' 'packagekit')
93
provides=('alpm-packagekit')
94
conflicts=('alpm-packagekit')
95
install=alpm-packagekit.install
96
97
cd alpm-dbus
98
install -Dm0755 target/release/libalpm_packagekit.so \
99
"$pkgdir/usr/lib/packagekit-backend/libpk_backend_alpm-dbus.so"
100
install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE.Apache-2.0.txt LICENSE.MIT.txt
101
}
102
Scan history
| Scanned at (UTC) | Severity | Rules |
|---|---|---|
| 2026-10-07 14:05:47 | Low | 1 |