anyps5-git

LOW

maintainer good_vibes 0 votes scanned 2026-10-17 00:21:55.226236

View on AUR

Why flagged

The package builds from source with mostly verifiable upstreams; the only risk is a prebuilt ffmpeg binary from a non-official release, but it is used as a library and not executed directly, limiting impact.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Low AI review llm_review

An AI model (qwen/qwen3-235b-a22b-2507) reviewed this and agrees it is LOW (confidence 95%): The package builds from source with mostly verifiable upstreams; the only risk is a prebuilt ffmpeg binary from a non-official release, but it is used as a library and not executed directly, limiting impact.

PKGBUILD

      1# Maintainer: Good Vibes <good_vibes@fastmail.com>
    
      2pkgname=anyps5-git
    
      3pkgver=0.1.1.r4590.g1e8fff68c
    
      4pkgrel=1
    
      5pkgdesc='Tool for porting PS5 executables to Linux and Windows (Git version)'
    
      6arch=('x86_64')
    
      7url='https://github.com/boykopovar/AnyPS5'
    
      8license=('GPL-2.0-only')
    
      9depends=('glibc' 'gcc-libs' 'libx11' 'libxext' 'libxcursor' 'libxi' 'libxfixes' 'libxrandr' 'libxss'
    
      10         'alsa-lib' 'libpulse' 'systemd-libs' 'dbus' 'vulkan-icd-loader')
    
      11makedepends=('git' 'cmake' 'ninja' 'python')
    
      12optdepends=('vulkan-driver: Vulkan GPU driver for running converted applications')
    
      13provides=('anyps5')
    
      14conflicts=('anyps5')
    
      15options=('!strip' '!debug' '!lto')
    
      16source=('README.md'
    
      17        '9ac4cfd195f1-ffmpeg-linux-x64.zip::https://github.com/KytyPS5/ext-ffmpeg-core/releases/download/9ac4cfd195f1/ffmpeg-linux-x64.zip'
    
      18        'AnyPS5::git+https://github.com/boykopovar/AnyPS5.git#branch=main'
    
      19        'SDL2::git+https://github.com/libsdl-org/SDL.git'
    
      20        'Vulkan-Headers::git+https://github.com/KhronosGroup/Vulkan-Headers.git'
    
      21        'SPIRV-Headers::git+https://github.com/KhronosGroup/SPIRV-Headers.git'
    
      22        'SPIRV-Tools::git+https://github.com/KhronosGroup/SPIRV-Tools.git'
    
      23        'glslang::git+https://github.com/KhronosGroup/glslang.git'
    
      24        'VulkanMemoryAllocator::git+https://github.com/GPUOpen-LibrariesAndSDKs/VulkanMemoryAllocator.git'
    
      25        'LibAtrac9::git+https://github.com/shadps4-emu/ext-LibAtrac9.git'
    
      26        'ffmpeg-core::git+https://github.com/KytyPS5/ext-ffmpeg-core.git'
    
      27        'freetype::git+https://github.com/freetype/freetype.git'
    
      28        'stb::git+https://github.com/nothings/stb.git'
    
      29        'libjpeg-turbo::git+https://github.com/libjpeg-turbo/libjpeg-turbo.git'
    
      30)
    
      31noextract=('9ac4cfd195f1-ffmpeg-linux-x64.zip')
    
      32sha256sums=('f84d1fbac69e1e252dc30e90227b2d9c3cc3e99a2e2f81e493d9a9829cd96126'
    
      33            'f4659ad09e6f2b99ecf0227ca56fe4bbb34572cdd8d85ff85384f74ba38f23ef'
    
      34            'SKIP'
    
      35            'SKIP'
    
      36            'SKIP'
    
      37            'SKIP'
    
      38            'SKIP'
    
      39            'SKIP'
    
      40            'SKIP'
    
      41            'SKIP'
    
      42            'SKIP'
    
      43            'SKIP'
    
      44            'SKIP'
    
      45            'SKIP'
    
      46)
    
      47
    
      48pkgver() {
    
      49  cd AnyPS5
    
      50  git describe --long --tags --match 'v[0-9]*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
    
      51}
    
      52
    
      53prepare() {
    
      54  mkdir -p ffmpeg-prebuilt
    
      55  bsdtar -xf "$srcdir/9ac4cfd195f1-ffmpeg-linux-x64.zip" -C ffmpeg-prebuilt
    
      56  cd AnyPS5
    
      57  git config submodule.3rdparty/SDL2.url "$srcdir/SDL2"
    
      58  git config submodule.3rdparty/Vulkan-Headers.url "$srcdir/Vulkan-Headers"
    
      59  git config submodule.3rdparty/SPIRV-Headers.url "$srcdir/SPIRV-Headers"
    
      60  git config submodule.3rdparty/SPIRV-Tools.url "$srcdir/SPIRV-Tools"
    
      61  git config submodule.3rdparty/glslang.url "$srcdir/glslang"
    
      62  git config submodule.3rdparty/VulkanMemoryAllocator.url "$srcdir/VulkanMemoryAllocator"
    
      63  git config submodule.3rdparty/LibAtrac9.url "$srcdir/LibAtrac9"
    
      64  git config submodule.3rdparty/ffmpeg-core.url "$srcdir/ffmpeg-core"
    
      65  git config submodule.3rdparty/freetype.url "$srcdir/freetype"
    
      66  git config submodule.3rdparty/stb.url "$srcdir/stb"
    
      67  git config submodule.3rdparty/libjpeg-turbo.url "$srcdir/libjpeg-turbo"
    
      68  git -c protocol.file.allow=always submodule update --init -- \
    
      69    3rdparty/{SDL2,Vulkan-Headers,SPIRV-Headers,SPIRV-Tools,glslang,VulkanMemoryAllocator,LibAtrac9,ffmpeg-core,freetype,stb,libjpeg-turbo}
    
      70}
    
      71
    
      72build() {
    
      73  cmake -S AnyPS5 -B build -G Ninja \
    
      74    -DCMAKE_BUILD_TYPE=Release \
    
      75    -DFFMPEG_PREBUILT_DIR="$srcdir/ffmpeg-prebuilt" \
    
      76    -DCMAKE_POLICY_VERSION_MINIMUM=3.5 \
    
      77    -DSDL_JACK=OFF \
    
      78    -DSDL_PIPEWIRE=OFF \
    
      79    -DSDL_SNDIO=OFF \
    
      80    -DSDL_LIBSAMPLERATE=OFF \
    
      81    -DBUILD_TESTING=OFF
    
      82  cmake --build build --target relinker libs
    
      83}
    
      84
    
      85check() {
    
      86  local test
    
      87  for test in optional_plt empty_tls tls_function_coverage linux_load_alignment windows_gui; do
    
      88    python "AnyPS5/core/relinker/relinker/tests/test_${test}.py" \
    
      89      "$srcdir/build/core/relinker/relinker"
    
      90  done
    
      91}
    
      92
    
      93package() {
    
      94  install -Dm755 build/core/relinker/relinker "$pkgdir/usr/bin/relinker"
    
      95  install -dm755 "$pkgdir/usr/lib/anyps5"
    
      96  install -m755 build/core/libs/libs/*.prx "$pkgdir/usr/lib/anyps5/"
    
      97  install -Dm644 ffmpeg-prebuilt/share/ffmpeg/copyright "$pkgdir/usr/share/licenses/$pkgname/ffmpeg/copyright"
    
      98  install -Dm644 ffmpeg-prebuilt/share/ffmpeg/SOURCE.txt "$pkgdir/usr/share/licenses/$pkgname/ffmpeg/SOURCE.txt"
    
      99  install -Dm644 AnyPS5/README.md "$pkgdir/usr/share/doc/anyps5/README.upstream.md"
    
      100  install -Dm644 README.md "$pkgdir/usr/share/doc/anyps5/README.md"
    
      101}
    
      102

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-17 00:21:55	Low	2
2026-10-16 00:12:47	Low	2
2026-10-15 00:28:05	Low	2
2026-10-14 00:06:47	Low	2
2026-10-13 00:23:45	Low	2
2026-10-12 00:18:51	Low	2
2026-10-11 13:10:50	Low	2