ardor-mouse

LOW

maintainer vitamindb 0 votes scanned 2026-09-23 15:40:39.984319

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Alexeyev Vitaly <vitamindbnfkz@gmail.com>
    
      2pkgname=ardor-mouse
    
      3pkgver=0.2.0
    
      4pkgrel=1
    
      5pkgdesc="Configuration tool for the ARDOR GAMING Edge Air Ultra mouse: DPI, RGB lighting, buttons, polling rate"
    
      6arch=('x86_64')
    
      7url="https://github.com/VitaminDB/ardor-mouse"
    
      8license=('MIT')
    
      9depends=('fontconfig' 'freetype2' 'libxkbcommon' 'wayland' 'vulkan-icd-loader' 'hicolor-icon-theme' 'gcc-libs' 'glibc')
    
      10optdepends=('libx11: X11 session' 'libxcursor: cursors in X11')
    
      11makedepends=('cargo' 'git')
    
      12options=('!lto' '!debug')
    
      13install=ardor-mouse.install
    
      14source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
    
      15sha256sums=('6c31bc2108ef610ef6315f9e56f20fa1ec4ceb4381f07565ffe4a03a5894e613')
    
      16
    
      17prepare() {
    
      18    cd "$pkgname-$pkgver"
    
      19    export RUSTUP_TOOLCHAIN=stable
    
      20    # syngui — git-зависимость; коммит закреплён в Cargo.lock
    
      21    cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
    
      22}
    
      23
    
      24build() {
    
      25    cd "$pkgname-$pkgver"
    
      26    export RUSTUP_TOOLCHAIN=stable
    
      27    export CARGO_TARGET_DIR=target
    
      28    cargo build --frozen --release
    
      29}
    
      30
    
      31check() {
    
      32    cd "$pkgname-$pkgver"
    
      33    export RUSTUP_TOOLCHAIN=stable
    
      34    export CARGO_TARGET_DIR=target
    
      35    cargo test --frozen --release
    
      36}
    
      37
    
      38package() {
    
      39    cd "$pkgname-$pkgver"
    
      40    install -Dm755 target/release/ardor_mouse "$pkgdir/usr/bin/ardor-mouse"
    
      41    install -Dm644 packaging/ardor-mouse.desktop "$pkgdir/usr/share/applications/ardor-mouse.desktop"
    
      42    install -Dm644 packaging/70-ardor-mouse.rules "$pkgdir/usr/lib/udev/rules.d/70-ardor-mouse.rules"
    
      43    install -Dm644 assets/icon/ardor-mouse.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/ardor-mouse.svg"
    
      44    for s in 16 32 48 64 128 256 512; do
    
      45        install -Dm644 "assets/icon/ardor-mouse-$s.png" \
    
      46            "$pkgdir/usr/share/icons/hicolor/${s}x${s}/apps/ardor-mouse.png"
    
      47    done
    
      48    install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
    
      49    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      50}
    
      51

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-23 15:40:39	Low	1