aria2-next-pro

LOW

maintainer NewYearPrism 0 votes scanned 2026-08-24 21:24:32.067303

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: NewYearPrism
    
      2
    
      3pkgname=aria2-next-pro
    
      4_pkgname=aria2-next
    
      5pkgver=2.5.9
    
      6pkgrel=2
    
      7pkgdesc='Maintained aria2 fork with extensive bug fixes and modernized architecture (with Aria2 Pro patches)'
    
      8arch=('x86_64' 'aarch64')
    
      9url='https://github.com/AnInsomniacy/aria2-next'
    
      10license=('GPL-2.0-or-later')
    
      11depends=(
    
      12    glibc
    
      13    libstdc++
    
      14    libgcc
    
      15)
    
      16makedepends=(
    
      17    cmake
    
      18    ninja
    
      19    patch
    
      20    make
    
      21    perl
    
      22)
    
      23provides=('aria2-next' 'aria2')
    
      24conflicts=('aria2-next' 'aria2')
    
      25source=(
    
      26    "${_pkgname}-${pkgver}.tar.gz::https://github.com/AnInsomniacy/aria2-next/archive/refs/tags/v${pkgver}.tar.gz"
    
      27    '0001-options-unlock-connection-per-server-limit.patch'
    
      28    '0002-download-retry-on-slow-speed-and-conection-close.patch'
    
      29    '0003-option-add-option-to-retry-on-http-400-403-406-or-un.patch'
    
      30)
    
      31sha512sums=(
    
      32    '8fa4a72ba58ceeec713c5e38458cbecc0eb6e58c0ef57a054b6304e4e167d1f916cdee6c43e444cc318a3b6c9eccb85c1431979c0a78aece2ca9184d82f110e0'
    
      33    'c6d257f2cf53e778f1f2fb5c3d2accb013b61e01b123806ea2b1ebbe0c8a085b4c4dbc43c44e1624a64ce353192adb2e5febfbe7581aa5580793cdb54b476e11'
    
      34    '014346d373604eb1c4ed77aa4eae33089d2d15de04a633c127e62e63869c77db4f012bd1fa5d4f60b8458a7a846b0c911c3ffbfcc954666c799a778995325e40'
    
      35    'fd0a7af20d140c6481a568c642771562b29ddfe0f49630bf1f101c3285a037bfb314a0f0a6673d4714526e10f6e9ffc799ac430eeb7da7ba185cfe706318a725'
    
      36)
    
      37options=(
    
      38    lto
    
      39    !debug
    
      40)
    
      41
    
      42prepare() {
    
      43  cd "${_pkgname}-${pkgver}"
    
      44
    
      45  local src
    
      46  for src in "${source[@]:1}"; do
    
      47    src="${src%%::*}"
    
      48    src="${src##*/}"
    
      49    patch -Np1 <"../${src}"
    
      50  done
    
      51}
    
      52
    
      53build() {
    
      54  CFLAGS+=" -ffile-prefix-map=${srcdir}=."
    
      55  CXXFLAGS+=" -ffile-prefix-map=${srcdir}=."
    
      56
    
      57  # Superbuild mode: all dependencies (zlib/expat/sqlite/c-ares/openssl/libssh2/
    
      58  # libtorrent) are built statically from third_party/ and linked into aria2,
    
      59  # which is why they are neither in depends nor makedepends.
    
      60  # Note: ARIA2_SUPERBUILD does not forward BUILD_SHARED_LIBS, so libaria2 is
    
      61  # built and installed as a static library; CMAKE_INTERPROCEDURAL_OPTIMIZATION
    
      62  # is not forwarded either, LTO is enabled via ARIA2_RELEASE_LTO instead.
    
      63  cmake -S "${_pkgname}-${pkgver}" -B build -G Ninja \
    
      64    -Wno-dev \
    
      65    -DCMAKE_BUILD_TYPE=None \
    
      66    -DBUILD_TESTING=OFF \
    
      67    -DARIA2_SUPERBUILD=ON \
    
      68    -DARIA2_ENABLE_LIBARIA2=ON \
    
      69    -DARIA2_RELEASE_LTO=ON
    
      70  cmake --build build
    
      71}
    
      72
    
      73package() {
    
      74  # The inner (non-superbuild) project lives in build/source and is configured
    
      75  # with CMAKE_INSTALL_PREFIX=<build>/dependencies, hence the --prefix override.
    
      76  DESTDIR="${pkgdir}" cmake --install build/source --prefix /usr
    
      77
    
      78  # libaria2.pc is generated with the vendored dependency prefix baked in
    
      79  sed -i 's|^prefix=.*|prefix=/usr|' \
    
      80    "${pkgdir}/usr/lib/pkgconfig/libaria2.pc"
    
      81
    
      82  ln -s "aria2-next" "${pkgdir}/usr/bin/aria2c"
    
      83}
    
      84

Scan history

Scanned at (UTC)	Severity	Rules
2026-08-24 21:24:32	Low	1