aurora-viewer-git

LOW

maintainer jesusokay 0 votes scanned 2026-10-30 17:56:37.877434

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Jesus <jesusaiyan@gmail.com>
    
      2pkgname=aurora-viewer-git
    
      3pkgver=0.8.4.beta.20261030.1.r28.gcafab5b80
    
      4pkgrel=1
    
      5pkgdesc='A modern Second Life viewer, written from scratch in Rust (Vulkan)'
    
      6arch=('x86_64')
    
      7url='https://aurora-viewer.org/'
    
      8license=('GPL-3.0-or-later')
    
      9depends=('vulkan-icd-loader' 'alsa-lib' 'libxkbcommon' 'wayland' 'libx11'
    
      10         'libxcursor' 'libxrandr' 'libxi' 'gstreamer' 'gst-plugins-base'
    
      11         'gst-plugins-good' 'gst-plugins-bad' 'gst-plugins-ugly' 'gst-libav'
    
      12         'nss' 'nspr' 'at-spi2-core' 'libcups' 'libxcomposite' 'libxdamage'
    
      13         'mesa' 'pango' 'cairo' 'hicolor-icon-theme' 'gcc-libs' 'glibc')
    
      14makedepends=('git' 'rust' 'cmake' 'clang' 'pkgconf')
    
      15provides=('aurora-viewer')
    
      16conflicts=('aurora-viewer')
    
      17# The final link is done with clang, which cannot consume the GCC LTO
    
      18# bytecode that makepkg's -flto=auto puts into C objects (e.g. mimalloc).
    
      19# Rust-code thin-LTO from Cargo.toml is unaffected.
    
      20options=('!lto')
    
      21source=("${pkgname}::git+https://github.com/Aurora-Viewer/Aurora-Viewer.git")
    
      22sha256sums=('SKIP')
    
      23
    
      24pkgver() {
    
      25  cd "${pkgname}"
    
      26  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
    
      27}
    
      28
    
      29build() {
    
      30  cd "${pkgname}"
    
      31  # aws-lc-sys compiles its jitterentropy source with its own -O0 and
    
      32  # #errors on any optimization; makepkg appends -O2 after it, so drop -O2
    
      33  # (other C files keep the optimization flags the crates pass themselves).
    
      34  export CFLAGS="${CFLAGS//-O2}" CXXFLAGS="${CXXFLAGS//-O2}"
    
      35  cargo build --release -p aurora-viewer
    
      36}
    
      37
    
      38package() {
    
      39  cd "${pkgname}"
    
      40  install -Dm755 target/release/aurora-viewer "${pkgdir}/usr/bin/aurora-viewer"
    
      41  install -Dm644 packaging/linux/aurora-viewer.desktop \
    
      42    "${pkgdir}/usr/share/applications/aurora-viewer.desktop"
    
      43  install -Dm644 assets/branding/aurora-logo.svg \
    
      44    "${pkgdir}/usr/share/icons/hicolor/scalable/apps/aurora-viewer.svg"
    
      45  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    
      46}
    
      47

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-30 17:56:37	Low	1