axolotl-apclient-git

LOW

maintainer hoxi 0 votes scanned 2026-10-29 17:53:05.425985

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: hoxi <mail@hoxi.me>
    
      2
    
      3pkgname=axolotl-apclient-git
    
      4_pkgname=axolotl
    
      5pkgver=0.1.6.r21.ga7c2620
    
      6pkgrel=1
    
      7pkgdesc="Lightweight Archipelago multiworld text client built with C++ and ImGui (git version)"
    
      8arch=('x86_64' 'aarch64')
    
      9url="https://github.com/mooinglemur/axolotl"
    
      10# MIT: axolotl, imgui, lua, sol2 (bundled); BSD-3-Clause: IXWebSocket (bundled)
    
      11license=('MIT' 'BSD-3-Clause')
    
      12depends=('gcc-libs' 'glibc' 'glfw' 'libglvnd' 'fontconfig' 'yaml-cpp' 'libzip' 'openssl' 'zlib')
    
      13makedepends=('git' 'cmake' 'ninja' 'python' 'nlohmann-json')
    
      14provides=("${pkgname%-git}=${pkgver%%.r*}")
    
      15conflicts=("${pkgname%-git}")
    
      16source=("git+$url.git"
    
      17        "imgui::git+https://github.com/ocornut/imgui.git"
    
      18        "IXWebSocket::git+https://github.com/machinezone/IXWebSocket.git"
    
      19        "sol2::git+https://github.com/ThePhD/sol2.git"
    
      20        "lua::git+https://github.com/lua/lua.git")
    
      21sha256sums=('SKIP'
    
      22            'SKIP'
    
      23            'SKIP'
    
      24            'SKIP'
    
      25            'SKIP')
    
      26
    
      27pkgver() {
    
      28  cd "$_pkgname"
    
      29  git describe --long --tags --match 'v[0-9]*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
    
      30}
    
      31
    
      32prepare() {
    
      33  cd "$_pkgname"
    
      34  git submodule init
    
      35  local mod
    
      36  for mod in imgui IXWebSocket sol2 lua; do
    
      37    git config "submodule.thirdparty/$mod.url" "$srcdir/$mod"
    
      38  done
    
      39  git -c protocol.file.allow=always submodule update
    
      40}
    
      41
    
      42build() {
    
      43  # The bundled lua checkout has no lua.hpp, so sol2 would pick up the
    
      44  # system one (different Lua version); include lua.h directly instead.
    
      45  CXXFLAGS+=" -DSOL_NO_LUA_HPP=1"
    
      46  cmake -B build -S "$_pkgname" -G Ninja \
    
      47    -DCMAKE_BUILD_TYPE=None \
    
      48    -DCMAKE_INSTALL_PREFIX=/usr \
    
      49    -DAXOLOTL_IGNORE_DIRTY=ON \
    
      50    -Wno-dev
    
      51  cmake --build build
    
      52}
    
      53
    
      54package() {
    
      55  DESTDIR="$pkgdir" cmake --install build
    
      56
    
      57  cd "$_pkgname"
    
      58  install -Dm644 com.mooinglemur.axolotl.desktop -t "$pkgdir/usr/share/applications"
    
      59  install -Dm644 com.mooinglemur.axolotl.png -t "$pkgdir/usr/share/icons/hicolor/256x256/apps"
    
      60
    
      61  install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      62  install -Dm644 thirdparty/imgui/LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE.imgui"
    
      63  install -Dm644 thirdparty/IXWebSocket/LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE.IXWebSocket"
    
      64  install -Dm644 thirdparty/sol2/LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE.sol2"
    
      65  sed -n '/^\* Copyright (C)/,/^\*\*\*\*/p' thirdparty/lua/lua.h \
    
      66    > "$pkgdir/usr/share/licenses/$pkgname/LICENSE.lua"
    
      67}
    
      68

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-29 17:53:05	Low	1