bearbar-git

LOW

maintainer tanay1337 0 votes scanned 2026-09-23 07:39:45.760256

View on AUR

Why flagged

The package builds from source via git from the project's own GitHub repository; the low severity is due to few votes and recent upload, but the build process is transparent and follows standard AUR practices.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Low AI review llm_review

An AI model (qwen/qwen3-235b-a22b-2507) reviewed this and agrees it is LOW (confidence 95%): The package builds from source via git from the project's own GitHub repository; the low severity is due to few votes and recent upload, but the build process is transparent and follows standard AUR practices.

PKGBUILD

      1# Maintainer: Tanay Pant <tanaypant@protonmail.com>
    
      2
    
      3pkgname=bearbar-git
    
      4pkgver=0.1.0.r2.ge9cf04b
    
      5pkgrel=1
    
      6pkgdesc="Compact GTK4 desktop bar for Hyprland, Niri, Sway, and KDE Plasma"
    
      7arch=('x86_64')
    
      8url="https://github.com/tanay1337/bearbar"
    
      9license=('MIT')
    
      10depends=(
    
      11    'glib2'
    
      12    'glibc'
    
      13    'gtk4>=4.12'
    
      14    'gtk4-layer-shell>=1'
    
      15    'libgcc'
    
      16    'libpulse'
    
      17    'upower'
    
      18)
    
      19makedepends=(
    
      20    'git'
    
      21    'rust>=1.92'
    
      22)
    
      23optdepends=(
    
      24    'bluez-utils: Bluetooth controls'
    
      25    'brightnessctl: brightness controls'
    
      26    'cliphist: clipboard history'
    
      27    'networkmanager: Wi-Fi controls'
    
      28    'pipewire: privacy indicators'
    
      29    'playerctl: media controls'
    
      30    'power-profiles-daemon: power profile controls'
    
      31    'swaync: notification count and panel integration'
    
      32    'wl-clipboard: clipboard history restoration'
    
      33)
    
      34provides=('bearbar')
    
      35conflicts=('bearbar')
    
      36options=('!debug')
    
      37source=("$pkgname::git+$url.git")
    
      38sha256sums=('SKIP')
    
      39
    
      40pkgver() {
    
      41    cd "$pkgname"
    
      42
    
      43    local _version
    
      44    _version=$(sed -n 's/^version = "\([^"]*\)"/\1/p' Cargo.toml | head -n 1)
    
      45    printf "%s.r%s.g%s" \
    
      46        "$_version" \
    
      47        "$(git rev-list --count HEAD)" \
    
      48        "$(git rev-parse --short=7 HEAD)"
    
      49}
    
      50
    
      51prepare() {
    
      52    cd "$pkgname"
    
      53
    
      54    export RUSTUP_TOOLCHAIN=stable
    
      55    cargo fetch --locked --target x86_64-unknown-linux-gnu
    
      56}
    
      57
    
      58build() {
    
      59    cd "$pkgname"
    
      60
    
      61    export CARGO_TARGET_DIR=target
    
      62    export RUSTUP_TOOLCHAIN=stable
    
      63    cargo build --frozen --release
    
      64}
    
      65
    
      66check() {
    
      67    cd "$pkgname"
    
      68
    
      69    export CARGO_TARGET_DIR=target
    
      70    export RUSTUP_TOOLCHAIN=stable
    
      71    cargo test --frozen --release --all-targets
    
      72}
    
      73
    
      74package() {
    
      75    cd "$pkgname"
    
      76
    
      77    install -Dm755 target/release/bearbar "$pkgdir/usr/bin/bearbar"
    
      78    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      79    install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
    
      80    install -Dm644 assets/bearbar-logo.svg \
    
      81        "$pkgdir/usr/share/doc/$pkgname/assets/bearbar-logo.svg"
    
      82    install -Dm644 examples/config.toml \
    
      83        "$pkgdir/usr/share/doc/$pkgname/examples/config.toml"
    
      84    install -Dm644 examples/config.apple.toml \
    
      85        "$pkgdir/usr/share/doc/$pkgname/examples/config.apple.toml"
    
      86    install -Dm644 examples/style.css \
    
      87        "$pkgdir/usr/share/doc/$pkgname/examples/style.css"
    
      88    install -Dm644 contrib/bearbar.service \
    
      89        "$pkgdir/usr/lib/systemd/user/bearbar.service"
    
      90    sed -i 's|ExecStart=%h/.local/bin/bearbar|ExecStart=/usr/bin/bearbar|' \
    
      91        "$pkgdir/usr/lib/systemd/user/bearbar.service"
    
      92}
    
      93

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-23 07:39:45	Low	2