bornopata

LOW

maintainer velox 0 votes scanned 2026-10-21 17:32:44.330620

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Andrew-Velox <mohabbat.bd2020@gmail.com>
    
      2pkgname=bornopata
    
      3pkgver=0.1.0_alpha.2
    
      4pkgrel=1
    
      5pkgdesc='Bangla (Avro phonetic) input method for Fcitx5 that learns your words'
    
      6arch=('x86_64')
    
      7url='https://github.com/Andrew-Velox/Bornopata'
    
      8license=('GPL-3.0-or-later' 'CC-BY-SA-4.0' 'LicenseRef-Character')
    
      9depends=('fcitx5' 'gcc-libs' 'glibc' 'hicolor-icon-theme' 'libxkbcommon' 'wayland')
    
      10makedepends=('cargo' 'cmake' 'gcc' 'git' 'nlohmann-json' 'pkgconf' 'python' 'systemd-libs' 'wayland-protocols')
    
      11install=bornopata.install
    
      12options=('!lto' '!debug')
    
      13_tag=${pkgver//_/-}
    
      14# The dictionary and the word pair model are not in the repository; the data releases pin them
    
      15# (assets/dictionary/words.bnd.release and lm.bnd.release).
    
      16source=("$pkgname-$_tag-source.tar.gz::$url/releases/download/v$_tag/$pkgname-$_tag-source.tar.gz"
    
      17        "words.bnd::$url/releases/download/data-v1/words.bnd"
    
      18        "lm.bnd::$url/releases/download/data-lm-v1/lm.bnd")
    
      19sha256sums=('fd56152d4e1ed9f22d053ba5a94c8f45627b0e257869798b6d43a6bbe346612b'
    
      20            'db0da0846c795e4339d4b3257cd79e65324a0de3fe06105079edc4d0a3aa064d'
    
      21            '60a8ef66dde12085a4626ace1b8d8b1dc955229882fd1fe3118774c8f339a733')
    
      22
    
      23prepare() {
    
      24  cd "$pkgname-$_tag"
    
      25  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
    
      26}
    
      27
    
      28build() {
    
      29  cd "$pkgname-$_tag"
    
      30  export RUSTUP_TOOLCHAIN=stable CARGO_TARGET_DIR=target
    
      31  cargo build --frozen --release -p borno-linux-server -p borno-settings
    
      32  apps/linux/scripts/build-gloss.sh target/gloss-en.bnd
    
      33  cmake -S apps/linux/fcitx5 -B target/fcitx5 -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_PREFIX=/usr -DBUILD_TESTING=OFF
    
      34  cmake --build target/fcitx5
    
      35}
    
      36
    
      37package() {
    
      38  cd "$pkgname-$_tag"
    
      39  install -Dm755 target/release/borno-linux-server "$pkgdir/usr/bin/borno-linux-server"
    
      40  install -Dm755 target/release/bornopata-settings "$pkgdir/usr/bin/bornopata-settings"
    
      41  DESTDIR="$pkgdir" cmake --install target/fcitx5
    
      42  install -Dm644 "$srcdir/words.bnd" "$pkgdir/usr/share/bornopata/words.bnd"
    
      43  install -Dm644 "$srcdir/lm.bnd" "$pkgdir/usr/share/bornopata/lm.bnd"
    
      44  install -Dm644 target/gloss-en.bnd "$pkgdir/usr/share/bornopata/gloss-en.bnd"
    
      45  sed 's|@PREFIX@|/usr|' apps/linux/systemd/bornopata.service |
    
      46    install -Dm644 /dev/stdin "$pkgdir/usr/lib/systemd/user/bornopata.service"
    
      47  sed 's|@PREFIX@|/usr|' apps/settings/linux/bornopata-settings.desktop |
    
      48    install -Dm644 /dev/stdin "$pkgdir/usr/share/applications/bornopata-settings.desktop"
    
      49  for icon in apps/settings/linux/icons/*/apps/bornopata.png; do
    
      50    install -Dm644 "$icon" "$pkgdir/usr/share/icons/hicolor/$(basename "$(dirname "$(dirname "$icon")")")/apps/bornopata.png"
    
      51  done
    
      52  local licenses="$pkgdir/usr/share/licenses/$pkgname"
    
      53  install -Dm644 LICENSE "$licenses/LICENSE"
    
      54  install -Dm644 NOTICE.md "$licenses/NOTICE.md"
    
      55  install -Dm644 assets/dictionary/ATTRIBUTION.txt "$licenses/DICTIONARY-ATTRIBUTION.txt"
    
      56  install -Dm644 assets/gloss/ATTRIBUTION.txt "$licenses/GLOSS-ATTRIBUTION.txt"
    
      57  install -Dm644 assets/emoji/LICENSE-unicode.txt "$licenses/EMOJI-LICENSE-UNICODE.txt"
    
      58}
    
      59

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-21 17:32:44	Low	1