bosphorus-git

LOW

maintainer cookiecaper 0 votes scanned 2026-09-16 09:21:46.704965

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Jeff Cook <jeff@jeffcook.io>
    
      2
    
      3pkgname=bosphorus-git
    
      4_pkgname=bosphorus
    
      5pkgver=3.2.0.r5.g52d0f19
    
      6pkgrel=1
    
      7pkgdesc='ANF simplifier and solver, and ANF-to-CNF converter'
    
      8arch=('x86_64')
    
      9url='https://github.com/meelgroup/bosphorus'
    
      10license=('MIT')
    
      11depends=('boost-libs' 'brial' 'cryptominisat' 'gcc-libs' 'glibc' 'm4ri')
    
      12makedepends=('boost' 'cmake' 'git' 'pkgconf' 'python')
    
      13checkdepends=('llvm')
    
      14provides=("${_pkgname}=${pkgver}")
    
      15conflicts=("${_pkgname}")
    
      16source=(
    
      17  "${_pkgname}::git+https://github.com/meelgroup/bosphorus.git"
    
      18  'cnf-utils::git+https://github.com/msoos/cnf-utils.git'
    
      19  'OutputCheck::git+https://github.com/msoos/OutputCheck.git'
    
      20)
    
      21b2sums=('SKIP' 'SKIP' 'SKIP')
    
      22
    
      23pkgver() {
    
      24  cd "${_pkgname}"
    
      25  git describe --long --tags --always \
    
      26    | sed -E 's#^release/##; s/^v//; s/([^-]*-g)/r\1/; s/-/./g'
    
      27}
    
      28
    
      29prepare() {
    
      30  cd "${_pkgname}"
    
      31  git submodule init
    
      32  git config submodule.utils/cnf-utils.url "${srcdir}/cnf-utils"
    
      33  git config submodule.utils/OutputCheck.url "${srcdir}/OutputCheck"
    
      34  git -c protocol.file.allow=always submodule update
    
      35}
    
      36
    
      37build() {
    
      38  # cryptominisat5_DIR must be set: empty means FetchContent of GitHub master.
    
      39  # CMAKE_BUILD_TYPE=None keeps makepkg CFLAGS/CXXFLAGS; skip install RPATH so
    
      40  # we do not ship the old extra package's broken RUNPATH of /usr/lib/libz.so.
    
      41  cmake -B build -S "${_pkgname}" \
    
      42    -DCMAKE_BUILD_TYPE=None \
    
      43    -DCMAKE_INSTALL_PREFIX=/usr \
    
      44    -Dcryptominisat5_DIR=/usr \
    
      45    -DENABLE_TESTING=ON \
    
      46    -DCMAKE_SKIP_INSTALL_RPATH=ON \
    
      47    -DCMAKE_EXPORT_NO_PACKAGE_REGISTRY=ON \
    
      48    -DPython3_EXECUTABLE=/usr/bin/python \
    
      49    -Wno-dev
    
      50  cmake --build build
    
      51}
    
      52
    
      53check() {
    
      54  ctest --test-dir build --output-on-failure
    
      55}
    
      56
    
      57package() {
    
      58  DESTDIR="${pkgdir}" cmake --install build
    
      59  install -Dm644 "${_pkgname}"/LICENSE* -t "${pkgdir}/usr/share/licenses/${pkgname}"
    
      60}
    
      61

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-16 09:21:46	Low	1