bufusb-cli

LOW

maintainer brysonak 0 votes scanned 2026-09-27 17:19:13.301701

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Bryson Kelly <brysonak@protonmail (dot) com>
    
      2pkgname=bufusb-cli
    
      3_binname=bufusb
    
      4pkgver=0.2.4
    
      5pkgrel=1
    
      6_srcdir="bufusb-$pkgver"
    
      7pkgdesc="A fast, safe bootable USB image flasher"
    
      8arch=('x86_64' 'aarch64')
    
      9url="https://github.com/brysonak/bufusb"
    
      10license=('GPL-3.0-or-later')
    
      11depends=('gcc-libs' 'glibc')
    
      12makedepends=('cargo')
    
      13optdepends=('ntfs-3g: NTFS fallback for ISOs with files over the FAT32 4 GiB limit')
    
      14replaces=('buf-cli')
    
      15conflicts=('buf-cli')
    
      16source=("$pkgname-$pkgver.tar.gz::https://github.com/brysonak/bufusb/archive/refs/tags/v$pkgver.tar.gz")
    
      17sha256sums=('656f6fb84bafe24b0584fb393dd3e8980d498e961b7ebfbf343cd768b4dafa5f')
    
      18
    
      19prepare() {
    
      20    cd "$_srcdir"
    
      21    export RUSTUP_TOOLCHAIN=stable
    
      22    cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
    
      23}
    
      24
    
      25build() {
    
      26    cd "$_srcdir"
    
      27    export RUSTUP_TOOLCHAIN=stable
    
      28    export CARGO_TARGET_DIR=target
    
      29    cargo build --frozen --release -p bufusb
    
      30}
    
      31
    
      32check() {
    
      33    cd "$_srcdir"
    
      34    export RUSTUP_TOOLCHAIN=stable
    
      35    cargo test --frozen --workspace
    
      36}
    
      37
    
      38package() {
    
      39    cd "$_srcdir"
    
      40    install -Dm755 "target/release/$_binname" "$pkgdir/usr/bin/$_binname"
    
      41    install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
    
      42    install -Dm644 docs/docs.md "$pkgdir/usr/share/doc/$pkgname/docs.md"
    
      43}
    
      44

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-27 17:19:13	Low	1