card-forge

LOW

maintainer couldLover 0 votes scanned 2026-10-07 14:05:47.471701

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: couldLover <https://github.com/numb747>
    
      2
    
      3pkgname=card-forge
    
      4pkgver=0.2.0
    
      5pkgrel=1
    
      6pkgdesc="Lightweight SillyTavern character card editor with image link caching (Rust/egui)"
    
      7arch=('x86_64' 'aarch64')
    
      8url="https://github.com/numb747/card-forge"
    
      9license=('GPL-3.0-only')
    
      10# OpenGL, Wayland and X11 libraries are loaded at runtime (dlopen) by winit/glutin.
    
      11depends=(
    
      12  'gcc-libs'
    
      13  'glibc'
    
      14  'hicolor-icon-theme'
    
      15  'libglvnd'
    
      16  'libx11'
    
      17  'libxcursor'
    
      18  'libxi'
    
      19  'libxkbcommon'
    
      20  'libxkbcommon-x11'
    
      21  'libxrandr'
    
      22  'wayland'
    
      23)
    
      24makedepends=('cargo')
    
      25optdepends=(
    
      26  'xdg-desktop-portal: open/save file dialogs'
    
      27  'xdg-utils: open images and folders in external apps'
    
      28  'noto-fonts-cjk: Chinese UI text'
    
      29  'fontconfig: locate a fallback CJK font'
    
      30)
    
      31# ring builds C/asm code that does not get along with makepkg's -flto flags.
    
      32options=('!lto')
    
      33source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
    
      34sha256sums=('67f8db698b6093b809bee52bf03be0fbdbf2ffeb67b69291dd339532ddbed4e9')
    
      35
    
      36prepare() {
    
      37  cd "$pkgname-$pkgver"
    
      38
    
      39  export RUSTUP_TOOLCHAIN=stable
    
      40  cargo fetch --locked --target "$(rustc --print host-tuple)"
    
      41}
    
      42
    
      43build() {
    
      44  cd "$pkgname-$pkgver"
    
      45
    
      46  export RUSTUP_TOOLCHAIN=stable
    
      47  export CARGO_TARGET_DIR=target
    
      48  # Build scripts embed absolute paths of generated files; keep $srcdir out of the binary.
    
      49  export RUSTFLAGS="$RUSTFLAGS --remap-path-prefix=$srcdir=/usr/src/debug/$pkgname"
    
      50  cargo build --frozen --release
    
      51}
    
      52
    
      53check() {
    
      54  cd "$pkgname-$pkgver"
    
      55
    
      56  export RUSTUP_TOOLCHAIN=stable
    
      57  export CARGO_TARGET_DIR=target
    
      58  export RUSTFLAGS="$RUSTFLAGS --remap-path-prefix=$srcdir=/usr/src/debug/$pkgname"
    
      59  cargo test --frozen --release
    
      60}
    
      61
    
      62package() {
    
      63  cd "$pkgname-$pkgver"
    
      64
    
      65  install -Dm755 target/release/card-forge "$pkgdir/usr/bin/card-forge"
    
      66  install -Dm644 assets/card-forge.desktop "$pkgdir/usr/share/applications/card-forge.desktop"
    
      67
    
      68  install -Dm644 assets/icons/card-forge.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/card-forge.svg"
    
      69  local size
    
      70  for size in 32 48 64 128 256 512; do
    
      71    install -Dm644 assets/icons/card-forge-$size.png \
    
      72      "$pkgdir/usr/share/icons/hicolor/${size}x${size}/apps/card-forge.png"
    
      73  done
    
      74
    
      75  install -Dm644 README.md README.zh-CN.md -t "$pkgdir/usr/share/doc/$pkgname"
    
      76  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      77}
    
      78

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-07 14:05:47	Low	1