ceasta

LOW

maintainer robertfoster 0 votes scanned 2026-09-25 11:11:47.608437

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: robertfoster
    
      2pkgname=ceasta
    
      3pkgver=0.10.0 # renovate: datasource=github-tags depName=ngwg/ceasta
    
      4pkgrel=1
    
      5pkgdesc="Disassembler, decompiler and debugger with a built-in MCP server"
    
      6arch=('x86_64')
    
      7url="https://github.com/ngwg/ceasta"
    
      8# ceasta itself; vendored lua, dear imgui (MIT) and capstone (BSD-3-Clause) are linked in
    
      9license=('GPL-3.0-only' 'MIT' 'BSD-3-Clause')
    
      10depends=('glfw' 'glibc' 'hicolor-icon-theme' 'libgcc' 'libgl' 'libstdc++')
    
      11makedepends=('cmake')
    
      12optdepends=('ttf-dejavu: DejaVu Sans Mono for the listing (falls back to the imgui built-in font)')
    
      13provides=("${pkgname}-cli")
    
      14conflicts=("${pkgname}-cli" "${pkgname}-bin" "${pkgname}-git")
    
      15source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz"
    
      16  "${pkgname}.desktop")
    
      17sha256sums=('f165e9f27eabcaa63e2f9c83fca56606e2127665ee5dffbf01b1cd216181af78'
    
      18            '4ea9ee523b63d0a9fb3ff2082ef008044dc7d5915a73a9c310231b7420b85ddc')
    
      19
    
      20build() {
    
      21  cmake -S "${pkgname}-${pkgver}" -B build \
    
      22    -DCMAKE_BUILD_TYPE=None \
    
      23    -DCEASTA_LINUX_GUI=ON \
    
      24    -Wno-dev
    
      25  cmake --build build
    
      26  # the gui is silently skipped when glfw / OpenGL are not found
    
      27  [[ -x build/ceasta ]]
    
      28}
    
      29
    
      30package() {
    
      31  cd "${pkgname}-${pkgver}"
    
      32
    
      33  install -Dm755 -t "${pkgdir}/usr/bin" ../build/ceasta-cli
    
      34
    
      35  # the gui loads plugins from plugins/ next to its /proc/self/exe path
    
      36  # (plus ~/.config/ceasta/plugins), so it lives in its own lib dir
    
      37  install -Dm755 -t "${pkgdir}/usr/lib/${pkgname}" ../build/ceasta
    
      38  ln -s "/usr/lib/${pkgname}/ceasta" "${pkgdir}/usr/bin/ceasta"
    
      39  install -Dm644 -t "${pkgdir}/usr/share/${pkgname}/plugins" plugins/*
    
      40  ln -s "/usr/share/${pkgname}/plugins" "${pkgdir}/usr/lib/${pkgname}/plugins"
    
      41
    
      42  install -Dm644 "${srcdir}/${pkgname}.desktop" \
    
      43    "${pkgdir}/usr/share/applications/${pkgname}.desktop"
    
      44  install -Dm644 docs/icon.svg \
    
      45    "${pkgdir}/usr/share/icons/hicolor/scalable/apps/${pkgname}.svg"
    
      46
    
      47  install -Dm644 -t "${pkgdir}/usr/share/doc/${pkgname}" \
    
      48    README.md docs/{CHANGELOG,lua,mcp}.md
    
      49  install -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgname}" \
    
      50    LICENSE docs/THIRD_PARTY_NOTICES.md
    
      51}
    
      52

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-25 11:11:47	Low	1