chaotixrecompiled-git

LOW

maintainer MilesWithTails 1 votes scanned 2026-10-24 15:40:54.697274

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: mileswithtails_ <gabmaykin@bk.ru>
    
      2pkgname=chaotixrecompiled-git
    
      3pkgver=0.15.1.r184.g1d4e22c
    
      4pkgrel=1
    
      5pkgdesc="Static recompilation of Knuckles' Chaotix (32X) with an SDL3 frontend (interpreter build; ROM required at first launch)"
    
      6arch=('x86_64' 'aarch64')
    
      7url="https://github.com/YuutaTsubasa/ChaotixRecompiled"
    
      8license=('MIT')
    
      9depends=('gcc-libs' 'glibc' 'sdl3' 'sdl3_ttf')
    
      10makedepends=('git' 'cmake' 'ninja')
    
      11optdepends=(
    
      12    'vulkan-icd-loader: Vulkan renderer'
    
      13    'mesa: OpenGL/Vulkan drivers for AMD/Intel GPUs'
    
      14    'nvidia-utils: Vulkan/OpenGL drivers for NVIDIA GPUs'
    
      15)
    
      16provides=('chaotixrecompiled')
    
      17conflicts=('chaotixrecompiled')
    
      18options=('!lto')
    
      19source=("$pkgname::git+https://github.com/YuutaTsubasa/ChaotixRecompiled.git")
    
      20sha256sums=('SKIP')
    
      21
    
      22pkgver() {
    
      23    cd "$pkgname"
    
      24    local ver
    
      25    ver=$(sed -n 's/^project(ChaotixRecompiled VERSION \([0-9][0-9.]*\).*/\1/p' CMakeLists.txt | head -n1)
    
      26    printf '%s.r%s.g%s' "$ver" \
    
      27        "$(git rev-list --count HEAD)" \
    
      28        "$(git rev-parse --short HEAD)"
    
      29}
    
      30
    
      31build() {
    
      32    cmake -S "$pkgname" -B build -G Ninja \
    
      33        -DCMAKE_BUILD_TYPE=None \
    
      34        -DCHAOTIX_BUILD_FRONTEND=ON \
    
      35        -DCHAOTIX_BUILD_TESTS=OFF \
    
      36        -DCHAOTIX_BUILD_TOOLS=OFF
    
      37    cmake --build build
    
      38}
    
      39
    
      40package() {
    
      41    install -Dm755 build/ChaotixRecompiled "$pkgdir/usr/bin/chaotixrecompiled"
    
      42
    
      43    install -Dm644 "$pkgname/assets/icon/icon.png" \
    
      44        "$pkgdir/usr/share/icons/hicolor/256x256/apps/chaotixrecompiled.png"
    
      45
    
      46    install -Dm644 "$pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      47
    
      48    install -d "$pkgdir/usr/share/applications"
    
      49    cat > "$pkgdir/usr/share/applications/chaotixrecompiled.desktop" <<'EOF'
    
      50[Desktop Entry]
    
      51Type=Application
    
      52Version=1.0
    
      53Name=Knuckles' Chaotix Recompiled
    
      54GenericName=32X Platform Game
    
      55Comment=Static recompilation of Knuckles' Chaotix (requires your own ROM)
    
      56Exec=env SDL_RENDER_DRIVER=vulkan,gpu,opengl chaotixrecompiled %f
    
      57TryExec=chaotixrecompiled
    
      58Icon=chaotixrecompiled
    
      59Terminal=false
    
      60Categories=Game;ArcadeGame;
    
      61Keywords=sonic;knuckles;chaotix;sega;32x;megadrive;genesis;
    
      62StartupNotify=true
    
      63EOF
    
      64}
    
      65

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-24 15:40:54	Low	1