chatwithwork-desktop-git

LOW

maintainer crmne 0 votes scanned 2026-10-24 07:39:45.568380

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Carmine Paolino <carmine@paolino.me>
    
      2pkgname=chatwithwork-desktop-git
    
      3pkgver=0.4.0
    
      4pkgrel=1
    
      5pkgdesc="Chat with Work Desktop: the desktop app, terminal interface and background agent (development version)"
    
      6arch=('x86_64' 'aarch64')
    
      7url="https://github.com/crmne/chatwithwork-desktop"
    
      8license=('MIT OR Apache-2.0')
    
      9install="${pkgname}.install"
    
      10depends=('alsa-lib' 'libpipewire' 'glibc' 'gcc-libs' 'webkit2gtk-4.1' 'gtk3' 'libayatana-appindicator' 'dbus')
    
      11makedepends=('git' 'cargo' 'pkgconf' 'cmake' 'clang')
    
      12optdepends=('org.freedesktop.secrets: store the device key in your keyring'
    
      13            'xdg-desktop-portal: native folder picker'
    
      14            'sane: scan with a USB scanner'
    
      15            'tesseract: make scans searchable (with tesseract-data-<language>)'
    
      16            'systemd: start the agent now and at login with cww daemon install')
    
      17provides=('cww' 'cww-app' 'chatwithwork-desktop')
    
      18conflicts=('cww' 'chatwithwork-desktop' 'chatwithwork-desktop-bin')
    
      19options=('!debug' '!lto')
    
      20source=("${pkgname}::git+https://github.com/crmne/chatwithwork-desktop.git")
    
      21sha256sums=('SKIP')
    
      22
    
      23pkgver() {
    
      24  cd "${srcdir}/${pkgname}"
    
      25  git describe --long --tags --abbrev=7 | sed 's/^v//;s/\-/.r/;s/\-g/./'
    
      26}
    
      27
    
      28prepare() {
    
      29  cd "${srcdir}/${pkgname}"
    
      30  export RUSTUP_TOOLCHAIN=stable
    
      31  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
    
      32}
    
      33
    
      34build() {
    
      35  cd "${srcdir}/${pkgname}"
    
      36  export RUSTUP_TOOLCHAIN=stable
    
      37  export CARGO_TARGET_DIR=target
    
      38  export RUSTFLAGS="${RUSTFLAGS:-} --remap-path-prefix=${srcdir}=/"
    
      39  cargo build --frozen --release --workspace
    
      40}
    
      41
    
      42check() {
    
      43  cd "${srcdir}/${pkgname}"
    
      44  export RUSTUP_TOOLCHAIN=stable
    
      45  export CARGO_TARGET_DIR=target
    
      46  cargo test --frozen --release --workspace
    
      47}
    
      48
    
      49package() {
    
      50  cd "${srcdir}/${pkgname}"
    
      51  install -Dm755 target/release/cww "${pkgdir}/usr/bin/cww"
    
      52  install -Dm755 target/release/cww-app "${pkgdir}/usr/bin/cww-app"
    
      53  install -Dm644 packaging/linux/cww-app.desktop "${pkgdir}/usr/share/applications/cww-app.desktop"
    
      54  install -Dm644 app/assets/mark.svg "${pkgdir}/usr/share/icons/hicolor/scalable/apps/cww-app.svg"
    
      55  install -Dm644 packaging/systemd/cww.service "${pkgdir}/usr/lib/systemd/user/cww.service"
    
      56  install -Dm644 README.md PROTOCOL.md SECURITY.md -t "${pkgdir}/usr/share/doc/${pkgname}/"
    
      57  install -Dm644 LICENSE-MIT LICENSE-APACHE -t "${pkgdir}/usr/share/licenses/${pkgname}/"
    
      58}
    
      59

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-24 07:39:45	Low	1