cindy-bin

LOW

maintainer czyt 0 votes scanned 2026-09-08 07:16:32.151301

View on AUR

Why flagged

The package installs a prebuilt .deb from the project's official GitHub releases, which is normal for distributing Electron apps; the dependencies and installed files are consistent with a legitimate desktop application, and there is no evidence of malicious behavior or remote code execution.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Low AI review llm_review

An AI model (qwen/qwen3-235b-a22b-2507) reviewed this and agrees it is LOW (confidence 95%): The package installs a prebuilt .deb from the project's official GitHub releases, which is normal for distributing Electron apps; the dependencies and installed files are consistent with a legitimate desktop application, and there is no evidence of malicious behavior or remote code execution.

PKGBUILD

      1# Maintainer: czyt <czytcn@gmail.com>
    
      2
    
      3pkgname=cindy-bin
    
      4pkgver=0.1.73
    
      5pkgrel=1
    
      6pkgdesc="Open-source AI agent that works out of the box (global edition)"
    
      7arch=('x86_64')
    
      8url="https://github.com/makecindy/cindy"
    
      9license=('Apache-2.0' 'MIT')
    
      10depends=(
    
      11  'alsa-lib' 'at-spi2-core' 'cairo' 'dbus' 'expat' 'glib2' 'glibc'
    
      12  'gtk3' 'libcups' 'libdrm' 'libgcc' 'libstdc++' 'libnotify' 'libx11' 'libxcb'
    
      13  'libxcomposite' 'libxdamage' 'libxext' 'libxfixes' 'libxkbcommon'
    
      14  'libxrandr' 'mesa' 'nspr' 'nss' 'pango' 'systemd-libs' 'xdg-utils'
    
      15)
    
      16makedepends=('libarchive')
    
      17optdepends=('libsecret: desktop credential storage')
    
      18provides=("cindy=${pkgver}")
    
      19conflicts=('cindy' 'cindy-cn-bin')
    
      20options=('!strip' '!debug')
    
      21
    
      22_deb="cindy-${pkgver}-linux-x64-global.deb"
    
      23source_x86_64=("${_deb}::${url}/releases/download/v${pkgver}/${_deb}")
    
      24sha256sums_x86_64=('41fd41f2cfa6e039145c6a391043b9982333155530898c9971022a65585d447c')
    
      25noextract=("${_deb}")
    
      26
    
      27package() {
    
      28  local data_archive
    
      29  data_archive=$(bsdtar -tf "${srcdir}/${_deb}" | awk '/^data\.tar(\.|$)/ {print}')
    
      30  [[ -n "$data_archive" && "$data_archive" != *$'\n'* ]] || return 1
    
      31  bsdtar -xOf "${srcdir}/${_deb}" "$data_archive" |
    
      32    bsdtar --no-same-owner -xf - -C "${pkgdir}" || return 1
    
      33
    
      34  install -Dm644 "${pkgdir}/usr/share/doc/cindy/copyright" \
    
      35    "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.electron"
    
      36  install -Dm644 "${pkgdir}/usr/lib/cindy/LICENSES.chromium.html" \
    
      37    "${pkgdir}/usr/share/licenses/${pkgname}/LICENSES.chromium.html"
    
      38  rm -r "${pkgdir}/usr/share/doc" "${pkgdir}/usr/share/lintian"
    
      39  # Windows-only development scripts are unused by the Linux prebuilt node-pty.
    
      40  rm -r "${pkgdir}/usr/lib/cindy/resources/app.asar.unpacked/node_modules/node-pty/deps/winpty"
    
      41  chmod 4755 "${pkgdir}/usr/lib/cindy/chrome-sandbox"
    
      42}
    
      43

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-08 07:16:32	Low	2