cinnabar

LOW

maintainer EinfxchFinn 1 votes scanned 2026-10-30 13:56:02.430493

View on AUR

Why flagged

The package builds from source hosted on GitHub, has few votes and was recently uploaded, but shows no signs of malicious behavior; dependencies and build process are typical for a Rust project.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Low AI review llm_review

An AI model (qwen/qwen3-235b-a22b-2507) reviewed this and agrees it is LOW (confidence 95%): The package builds from source hosted on GitHub, has few votes and was recently uploaded, but shows no signs of malicious behavior; dependencies and build process are typical for a Rust project.

PKGBUILD

      1# Maintainer: Finn Künstner <finn dot kuenstner at gmail dot com>
    
      2
    
      3pkgname=cinnabar
    
      4pkgver=0.1.31
    
      5pkgrel=1
    
      6pkgdesc='Unofficial client compatible with Minecraft: Bedrock Edition, written in Rust'
    
      7arch=('x86_64')
    
      8url='https://github.com/cinnabar-mc/cinnabar'
    
      9license=('PolyForm-Noncommercial-1.0.0')
    
      10depends=(
    
      11  'alsa-lib'
    
      12  'glibc'
    
      13  'hicolor-icon-theme'
    
      14  'libgcc'
    
      15  'libglvnd'
    
      16  'libx11'
    
      17  'libxcursor'
    
      18  'libxi'
    
      19  'libxkbcommon'
    
      20  'libxkbcommon-x11'
    
      21  'systemd-libs'
    
      22  'vulkan-driver'
    
      23  'vulkan-icd-loader'
    
      24  'wayland'
    
      25)
    
      26makedepends=('cargo' 'git' 'go')
    
      27optdepends=(
    
      28  'kdialog: file picker and dialogs without an XDG portal'
    
      29  'pipewire-alsa: sound on PipeWire'
    
      30  'pulseaudio-alsa: sound on PulseAudio'
    
      31  'xdg-utils: open links and accept Discord invites'
    
      32  'zenity: file picker and dialogs without an XDG portal'
    
      33)
    
      34options=('!debug' '!lto' '!strip')
    
      35source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
    
      36sha256sums=('f04219c90ab15e6c99a2c88852c00caa95012a960e79018ef0d11574afbbef55')
    
      37
    
      38prepare() {
    
      39  cd "$pkgname-$pkgver"
    
      40
    
      41  export RUSTUP_TOOLCHAIN=stable
    
      42  cargo fetch --locked --target "$(rustc --print host-tuple)"
    
      43
    
      44  export GOPATH="$srcdir/go"
    
      45  go mod download -modcacherw
    
      46  (cd tools/localserver && GOWORK=off go mod download -modcacherw)
    
      47}
    
      48
    
      49build() {
    
      50  cd "$pkgname-$pkgver"
    
      51
    
      52  export CINNABAR_BUILD_COMMIT=$(gzip -dc "$srcdir/$pkgname-$pkgver.tar.gz" | git get-tar-commit-id)
    
      53
    
      54  export RUSTUP_TOOLCHAIN=stable
    
      55  export CARGO_TARGET_DIR="$PWD/target"
    
      56  export CARGO_BUILD_BUILD_DIR="$CARGO_TARGET_DIR"
    
      57  export CARGO_PROFILE_RELEASE_DEBUG=false
    
      58  export RUSTFLAGS+=" --remap-path-prefix=$srcdir=/build --remap-path-prefix=${CARGO_HOME:-$HOME/.cargo}=/cargo"
    
      59  cargo build --frozen --release --no-default-features \
    
      60    $(awk '$2 != "-" {printf "-p %s --bin %s ", $2, $1}' packaging/common/runtime-binaries.txt) \
    
      61    -p asset-compiler --bin assetc
    
      62
    
      63  export GOPATH="$srcdir/go"
    
      64  export CGO_CPPFLAGS="$CPPFLAGS"
    
      65  export CGO_CFLAGS="$CFLAGS"
    
      66  export CGO_CXXFLAGS="$CXXFLAGS"
    
      67  export CGO_LDFLAGS="$LDFLAGS"
    
      68  export GOFLAGS='-buildmode=pie -trimpath -mod=readonly -modcacherw'
    
      69  go build -ldflags "-linkmode=external -s -w $(bash packaging/common/core-ldflags.sh)" \
    
      70    -o "$CARGO_TARGET_DIR/release/bedrock-core" ./core/cmd/bedrock-core
    
      71  cd tools/localserver
    
      72  GOWORK=off go build -ldflags '-linkmode=external -s -w' \
    
      73    -o "$CARGO_TARGET_DIR/release/bedrock-local-server" .
    
      74}
    
      75
    
      76package() {
    
      77  cd "$pkgname-$pkgver"
    
      78
    
      79  (
    
      80    source packaging/common/stage-payload.sh
    
      81    stage_runtime_binaries "$pkgdir/usr/lib/$pkgname/bin"
    
      82    stage_resources "$pkgdir/usr/lib/$pkgname/share/$pkgname" target/release/assetc
    
      83  )
    
      84  install -d "$pkgdir/usr/bin"
    
      85  ln -s "/usr/lib/$pkgname/bin/$pkgname" "$pkgdir/usr/bin/$pkgname"
    
      86
    
      87  install -Dm644 "packaging/linux/$pkgname.desktop" -t "$pkgdir/usr/share/applications"
    
      88  install -Dm644 "packaging/icons/$pkgname.svg" -t "$pkgdir/usr/share/icons/hicolor/scalable/apps"
    
      89  install -Dm644 LICENSE THIRD_PARTY_NOTICES.md -t "$pkgdir/usr/share/licenses/$pkgname"
    
      90}
    
      91

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-30 13:56:02	Low	2