computer-use-linux

LOW

maintainer rubin55 0 votes scanned 2026-09-05 22:01:36.851925

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer:  Rubin Simons <me@rubin55.org>
    
      2
    
      3pkgname=computer-use-linux
    
      4pkgver=0.5.0
    
      5pkgrel=1
    
      6pkgdesc="Control a real Linux desktop from any MCP host (AT-SPI, portals, multi-compositor window targeting)"
    
      7arch=('x86_64' 'aarch64')
    
      8url="https://github.com/agent-sh/computer-use-linux"
    
      9license=('MIT')
    
      10depends=('at-spi2-core' 'gcc-libs' 'glibc')
    
      11makedepends=('cargo')
    
      12checkdepends=('dbus')
    
      13optdepends=(
    
      14    'gnome-screenshot: screenshot fallback for background sessions'
    
      15    'hyprland: window targeting on Hyprland'
    
      16    'i3-wm: window targeting on i3'
    
      17    'sway: window targeting on Sway'
    
      18    'wmctrl: window management on generic X11/EWMH'
    
      19    'wtype: text input on wlroots compositors'
    
      20    'xdotool: keyboard input on X11 sessions'
    
      21    'xorg-xprop: window PID hydration on X11'
    
      22    'ydotool: input fallback when the RemoteDesktop portal is unavailable'
    
      23)
    
      24conflicts=('computer-use-linux-bin')
    
      25source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz")
    
      26sha256sums=('d7f0be220a8e9e0d2ebc8bb64705b3b67ccdf7458c75bb3964173613b0d56a08')
    
      27
    
      28prepare() {
    
      29    cd "${pkgname}-${pkgver}"
    
      30    export RUSTUP_TOOLCHAIN=stable
    
      31
    
      32    cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
    
      33}
    
      34
    
      35build() {
    
      36    cd "${pkgname}-${pkgver}"
    
      37    export RUSTUP_TOOLCHAIN=stable
    
      38
    
      39    # mimalloc builds its C sources with the cc crate; GCC LTO objects hide
    
      40    # those symbols from rust-lld and linking fails with undefined mi_*
    
      41    # references.
    
      42    export CFLAGS="${CFLAGS//-flto=auto/}"
    
      43    export CXXFLAGS="${CXXFLAGS//-flto=auto/}"
    
      44
    
      45    # Upstream strips symbols via [profile.release]; keep DWARF so the
    
      46    # global !strip/debug OPTIONS stay meaningful for Rust binaries.
    
      47    export CARGO_PROFILE_RELEASE_STRIP=none
    
      48    export CARGO_PROFILE_RELEASE_DEBUG=2
    
      49
    
      50    cargo build --frozen --release
    
      51}
    
      52
    
      53check() {
    
      54    cd "${pkgname}-${pkgver}"
    
      55    export RUSTUP_TOOLCHAIN=stable
    
      56
    
      57    # The KWin backend tests spawn a private dbus-daemon (see checkdepends).
    
      58    cargo test --frozen --release
    
      59}
    
      60
    
      61package() {
    
      62    cd "${pkgname}-${pkgver}"
    
      63    install -Dm755 "target/release/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
    
      64    install -Dm755 "target/release/${pkgname}-cosmic" "${pkgdir}/usr/bin/${pkgname}-cosmic"
    
      65    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    
      66}
    
      67

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-05 22:01:36	Low	1