crit

LOW

maintainer roscar 0 votes scanned 2026-10-21 05:30:25.801317

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Robert Rosca <robert@rosca.dev>
    
      2
    
      3pkgname=crit
    
      4pkgver=0.23.0
    
      5pkgrel=1
    
      6pkgdesc="Review AI coding agents' plans, diffs and running apps in the browser, local-first"
    
      7arch=('x86_64' 'aarch64')
    
      8url='https://github.com/tomasz-tomczyk/crit'
    
      9license=('MIT')
    
      10depends=('glibc' 'git')
    
      11makedepends=('go>=2:1.26')
    
      12checkdepends=('git')
    
      13optdepends=('github-cli: GitHub PR comment sync'
    
      14            'glab: GitLab MR comment sync'
    
      15            'jujutsu: jj repository support'
    
      16            'sapling-scm: Sapling repository support'
    
      17            'xdg-utils: open reviews in the browser'
    
      18            'libnotify: desktop notifications'
    
      19            'xdg-user-dirs: locate Documents dir for crit install')
    
      20options=(!lto)
    
      21source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz")
    
      22sha256sums=('4b1c0f9835f752ac07014ef306a60051f4fb1839f1911f8916eceff0938f2383')
    
      23
    
      24prepare() {
    
      25  cd "${pkgname}-${pkgver}"
    
      26  export GOPATH="${srcdir}/gopath" GOTOOLCHAIN=local GOFLAGS="-modcacherw"
    
      27  go mod download
    
      28}
    
      29
    
      30build() {
    
      31  # Get the commit from the GitHub archives pax header
    
      32  local _commit
    
      33  _commit=$(zcat "${pkgname}-${pkgver}.tar.gz" | git get-tar-commit-id)
    
      34
    
      35  cd "${pkgname}-${pkgver}"
    
      36  export GOPATH="${srcdir}/gopath" GOTOOLCHAIN=local
    
      37  export CGO_CPPFLAGS="${CPPFLAGS}" CGO_CFLAGS="${CFLAGS}" \
    
      38         CGO_CXXFLAGS="${CXXFLAGS}" CGO_LDFLAGS="${LDFLAGS}"
    
      39  # -buildvcs=false: don't stamp the enclosing packaging repo's revision into
    
      40  # the binary as upstream version info is passed explicitly via -ldflags
    
      41  export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw -buildvcs=false"
    
      42  # main.date is the build time (makepkg's SOURCE_DATE_EPOCH), not the release date.
    
      43  go build \
    
      44    -ldflags "-linkmode=external -X main.version=${pkgver} -X main.commit=${_commit:0:7} -X main.date=$(date -u -d "@${SOURCE_DATE_EPOCH}" +%F)" \
    
      45    -o "${pkgname}" ./cmd/crit
    
      46}
    
      47
    
      48check() {
    
      49  cd "${pkgname}-${pkgver}"
    
      50  export GOPATH="${srcdir}/gopath" GOTOOLCHAIN=local GOFLAGS="-modcacherw"
    
      51  # Tests detect default branch from the cwd's repo which causes issues,
    
      52  # making a repo for the tests to run in solves this
    
      53  git init -q
    
      54  go test ./...
    
      55}
    
      56
    
      57package() {
    
      58  cd "${pkgname}-${pkgver}"
    
      59  install -Dm755 "${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
    
      60  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    
      61  install -Dm644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README.md"
    
      62}
    
      63

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-21 05:30:25	Low	1