damask

maintainer MartinDiehl · 2 votes · scanned 2026-08-03 00:08:14.047287

LOW

Why flagged The source is downloaded from the project's official domain (damask-multiphysics.org), which is not on the whitelist but is plausibly legitimate; the package builds from source, which is normal AUR behavior, and there is no evidence of malicious or unverifiable code execution.

Triggered rules

LOW AI review downgraded a static finding llm_review

The static rules flagged this MEDIUM, but an AI model (qwen/qwen3-235b-a22b-2507) reviewed the full PKGBUILD and judged it LOW (confidence 95%): The source is downloaded from the project's official domain (damask-multiphysics.org), which is not on the whitelist but is plausibly legitimate; the package builds from source, which is normal AUR behavior, and there is no evidence of malicious or unverifiable code execution.

1 higher static finding superseded - not the current verdict (shown for transparency)

MEDIUM source=() URL on a non-standard host source_untrusted_domain

One or more source=() URLs point to a host outside the trusted allowlist (github.com, gitlab.com, codeberg.org, pypi.org, …).

PKGBUILD:17 source=(https://damask-multiphysics.org/download/damask-${pkgver}.tar.xz

PKGBUILD

1 offending line(s) highlighted

      1# Maintainer: Martin Diehl <martin.diehl@kuleuven.be>
    
      2pkgbase=damask
    
      3pkgname=('damask' 'damask-grid' 'damask-mesh' 'python-damask')
    
      4pkgver=3.1.0
    
      5pkgrel=2
    
      6pkgdesc='DAMASK - The Duesseldorf Advanced Material Simulation Kit'
    
      7arch=('x86_64')
    
      8url='https://damask-multiphysics.org'
    
      9license=('AGPL-3.0-or-later')
    
      10petsc_excluded='3.26' # next PETSc release (exclude because API changes are expected)
    
      11makedepends=('gcc-fortran' 'cmake'
    
      12             'python-build' 'python-installer' 'python-wheel' 'python-setuptools'
    
      13             "petsc<${petsc_excluded}" 'hdf5-openmpi' 'fftw-openmpi' 'zlib' 'libfyaml'
    
      14             'python-pandas' 'python-numpy' 'python-scipy' 'python-h5py-openmpi' 'python-matplotlib' 'python-pyaml'
    
      15             'vtk' 'fmt' 'verdict')
    
      16optdepends=('paraview: post-processing')
    
      17source=(https://damask-multiphysics.org/download/damask-${pkgver}.tar.xz
    
      18       'DAMASK_grid.1'
    
      19       'DAMASK_mesh.1')
    
      20
    
      21sha512sums=('7e00d655601ab1c097505e4202713f0708bd6137b01fc5e47b162d788399fb95669c39f6df79bb699ede87fce502011f94cec37839cd774fb54a8b7dd1a5aeab'
    
      22            'd41eaae25bfb428661cb121ff89b80c6f146c997df40e1bd8736381c1ae73c0535d0886d6586edf34bb55d47629efa27d23058a044363c33f383f9ab097b91a4'
    
      23            '5ed3d30432a3999894f137da0eeed73985c3ba7155458b3c25dbda2b91b44c23a821da880881c71cd224945133ed8290da04ee1caa079533e746b6d0070e46be')
    
      24
    
      25prepare() {
    
      26  sed -i 's#fs_case_sensitive(${CMAKE_INSTALL_PREFIX}/bin fs_is_case_sensitive)#set(fs_is_case_sensitive BOOL FALSE)#g' ${pkgname}-${pkgver}/src/CMakeLists.txt
    
      27}
    
      28
    
      29build() {
    
      30  cmake -S ${pkgbase}-${pkgver} \
    
      31        -B build-test \
    
      32        -D TEST=ON \
    
      33        -D CMAKE_INSTALL_PREFIX:PATH=/usr \
    
      34        -D CMAKE_BUILD_TYPE:STRING=Performance
    
      35  make -C build-test
    
      36
    
      37  cmake -S ${pkgbase}-${pkgver} \
    
      38        -B build-grid \
    
      39        -D GRID=ON \
    
      40        -D CMAKE_INSTALL_PREFIX:PATH=/usr \
    
      41        -D CMAKE_BUILD_TYPE:STRING=Performance
    
      42  make -C build-grid
    
      43
    
      44  cmake -S ${pkgbase}-${pkgver} \
    
      45        -B build-mesh \
    
      46        -D MESH=ON \
    
      47        -D CMAKE_INSTALL_PREFIX:PATH=/usr \
    
      48        -D CMAKE_BUILD_TYPE:STRING=Performance
    
      49  make -C build-mesh
    
      50
    
      51  cd ${pkgbase}-${pkgver}/python
    
      52  python -m build --wheel --no-isolation
    
      53}
    
      54
    
      55check() {
    
      56  mpirun -np 2 build-test/src/DAMASK_test
    
      57
    
      58  example_dir="$(pwd)"/${pkgbase}-${pkgver}/examples/grid
    
      59  mpirun -np 2 build-grid/src/DAMASK_grid \
    
      60         -l "${example_dir}"/tensionX.yaml \
    
      61         -g "${example_dir}"/20grains16x16x16.vti \
    
      62         -m "${example_dir}"/material.yaml \
    
      63         -w $(mktemp -d)
    
      64
    
      65  example_dir="$(pwd)"/${pkgbase}-${pkgver}/examples/mesh
    
      66  ./build-mesh/src/DAMASK_mesh \
    
      67         -l "${example_dir}"/tensionZ_3g.yaml \
    
      68         -g "${example_dir}"/cube_3grains.msh \
    
      69         -m "${example_dir}"/material.yaml \
    
      70         -w $(mktemp -d)
    
      71
    
      72  PYTHONPATH=${pkgbase}-${pkgver}/python:"${PYTHONPATH}"
    
      73  python -c "import damask;print(damask.__version__)"
    
      74}
    
      75
    
      76package_damask-grid() {
    
      77  pkgdesc='Grid solver for DAMASK'
    
      78  depends=("petsc<${petsc_excluded}" 'openmpi' 'hdf5-openmpi' 'libfyaml' 'zlib' 'fftw-openmpi')
    
      79  optdepends=('dream3d: pre-processing')
    
      80
    
      81  install -m 644 -D ${pkgbase}-${pkgver}/examples/grid/* -t "${pkgdir}"/usr/share/doc/${pkgname}/
    
      82  install -m 644 -D DAMASK_grid.1 -t "${pkgdir}"/usr/share/man/man1/
    
      83  install -m 644 -D DAMASK_grid.1 -T "${pkgdir}"/usr/share/man/man1/damask_grid.1
    
      84  install -m 644 -D  ${pkgbase}-${pkgver}/env/damask_grid -t "${pkgdir}"/usr/share/bash-completion/completions/
    
      85  install -m 644 -D  ${pkgbase}-${pkgver}/env/_damask_grid -t "${pkgdir}"/usr/share/zsh/site-functions/
    
      86
    
      87  DESTDIR="${pkgdir}" cmake --install build-grid
    
      88  ln -s DAMASK_grid "${pkgdir}"/usr/bin/damask_grid
    
      89}
    
      90
    
      91package_damask-mesh() {
    
      92  pkgdesc='Mesh solver for DAMASK'
    
      93  depends=("petsc<${petsc_excluded}" 'openmpi' 'hdf5-openmpi' 'libfyaml')
    
      94  optdepends=('neper: pre-processing')
    
      95
    
      96  install -m 644 -D ${pkgbase}-${pkgver}/examples/mesh/* -t "${pkgdir}"/usr/share/doc/${pkgname}/
    
      97  install -m 644 -D DAMASK_mesh.1 -t "${pkgdir}"/usr/share/man/man1/
    
      98  install -m 644 -D DAMASK_mesh.1 -T "${pkgdir}"/usr/share/man/man1/damask_mesh.1
    
      99  install -m 644 -D  ${pkgbase}-${pkgver}/env/damask_mesh -t "${pkgdir}"/usr/share/bash-completion/completions/
    
      100  install -m 644 -D  ${pkgbase}-${pkgver}/env/_damask_mesh -t "${pkgdir}"/usr/share/zsh/site-functions/
    
      101
    
      102  DESTDIR="${pkgdir}" cmake --install build-mesh
    
      103  ln -s DAMASK_mesh "${pkgdir}"/usr/bin/damask_mesh
    
      104}
    
      105
    
      106package_python-damask() {
    
      107  pkgdesc='Pre- and post-processing tools for DAMASK'
    
      108  depends=('python-pandas' 'python-numpy' 'python-scipy' 'python-h5py-openmpi' 'vtk' 'python-matplotlib' 'python-pyaml')
    
      109  optdepends=('python-seaborn: post-processing'
    
      110              'jupyterlab: comfortable shell'
    
      111              'ipython: comfortable shell')
    
      112
    
      113  python -m installer --destdir="${pkgdir}" ${pkgbase}-${pkgver}/python/dist/*.whl
    
      114}
    
      115
    
      116package_damask() {
    
      117  depends=('python-damask' 'damask-grid' 'damask-mesh')
    
      118
    
      119  install -m 755 -d "${pkgdir}"/usr/share/doc/${pkgname}/
    
      120  cp -r ${pkgbase}-${pkgver}/examples/config/* ${pkgdir}/usr/share/doc/${pkgname}/
    
      121
    
      122}
    
      123

Scan history

Scanned at (UTC)	Severity	Rules
2026-08-03 00:08:14	LOW	2
2026-08-02 00:16:08	LOW	2
2026-08-01 00:11:18	LOW	2
2026-07-31 00:14:10	LOW	2
2026-07-30 00:17:23	LOW	2
2026-07-29 00:25:53	LOW	2
2026-07-28 00:07:28	LOW	2
2026-07-27 00:24:32	LOW	2
2026-07-26 00:07:32	LOW	2
2026-07-25 00:13:44	LOW	2
2026-07-24 00:02:28	LOW	2
2026-07-23 00:14:47	LOW	2
2026-07-22 00:29:32	LOW	2
2026-07-21 00:24:15	LOW	2
2026-07-20 00:19:49	LOW	2
2026-07-19 00:17:08	LOW	2
2026-07-18 00:14:48	LOW	2
2026-07-17 00:06:16	LOW	2
2026-07-16 00:05:41	LOW	2
2026-07-15 00:09:25	LOW	2