dfdu-git

LOW

maintainer hooger 0 votes scanned 2026-11-04 02:05:35.233463

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Jordon de Hoog <jordon.dehoog@gmail.com>
    
      2pkgname=dfdu-git
    
      3pkgver=0.5.0
    
      4pkgrel=1
    
      5pkgdesc="Disk usage browser for the terminal (latest commit)"
    
      6arch=('x86_64' 'aarch64')
    
      7url="https://github.com/jordond/dfdu"
    
      8license=('MIT')
    
      9depends=('gcc-libs' 'glibc')
    
      10makedepends=('cargo' 'git')
    
      11provides=('dfdu')
    
      12conflicts=('dfdu')
    
      13options=('!lto')
    
      14source=("$pkgname::git+$url.git")
    
      15sha256sums=('SKIP')
    
      16
    
      17pkgver() {
    
      18    cd "$pkgname"
    
      19    git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
    
      20}
    
      21
    
      22prepare() {
    
      23    cd "$pkgname"
    
      24    export RUSTUP_TOOLCHAIN=stable
    
      25    cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
    
      26}
    
      27
    
      28build() {
    
      29    cd "$pkgname"
    
      30    export RUSTUP_TOOLCHAIN=stable
    
      31    export CARGO_TARGET_DIR=target
    
      32    cargo build --frozen --release -p dfdu
    
      33}
    
      34
    
      35package() {
    
      36    cd "$pkgname"
    
      37    install -Dm755 target/release/dfdu "$pkgdir/usr/bin/dfdu"
    
      38    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      39    install -Dm644 assets/man/*.1 -t "$pkgdir/usr/share/man/man1"
    
      40    install -Dm644 assets/completions/dfdu.bash "$pkgdir/usr/share/bash-completion/completions/dfdu"
    
      41    install -Dm644 assets/completions/_dfdu "$pkgdir/usr/share/zsh/site-functions/_dfdu"
    
      42    install -Dm644 assets/completions/dfdu.fish "$pkgdir/usr/share/fish/vendor_completions.d/dfdu.fish"
    
      43}
    
      44

Scan history

Scanned at (UTC)	Severity	Rules
2026-11-04 02:05:35	Low	1