dirt

LOW

maintainer kohbo 1 votes scanned 2026-10-19 01:23:43.518710

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: kohbo <kohbosan@gmail.com>
    
      2
    
      3pkgname=dirt
    
      4pkgver=0.10.1
    
      5pkgrel=1
    
      6pkgdesc='k9s-style TUI for libvirt / KVM virtual machines, with htop-style live stats'
    
      7arch=('x86_64' 'aarch64')
    
      8url='https://github.com/llcoolkm/dirt'
    
      9license=('GPL-3.0-only')
    
      10depends=('libvirt' 'glibc')
    
      11makedepends=('go')
    
      12options=('!lto')
    
      13optdepends=(
    
      14  'virt-install: clone VMs (virt-clone)'
    
      15  'virt-viewer: graphical console'
    
      16  'openssh: SSH into guests'
    
      17  'qemu-img: disk image info'
    
      18)
    
      19source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
    
      20sha256sums=('3cd988413adb033ee2380bb2baa17b0db87a2ac90a756d93d2b0d5c7a65cb282')
    
      21
    
      22prepare() {
    
      23  cd "$pkgname-$pkgver"
    
      24  export GOPATH="$srcdir/gopath"
    
      25  export GOFLAGS='-modcacherw'
    
      26  go mod download
    
      27}
    
      28
    
      29build() {
    
      30  cd "$pkgname-$pkgver"
    
      31  export GOPATH="$srcdir/gopath"
    
      32  export CGO_CPPFLAGS="${CPPFLAGS}"
    
      33  export CGO_CFLAGS="${CFLAGS}"
    
      34  export CGO_CXXFLAGS="${CXXFLAGS}"
    
      35  export CGO_LDFLAGS="${LDFLAGS}"
    
      36  export GOFLAGS='-buildmode=pie -trimpath -mod=readonly -modcacherw'
    
      37  go build -ldflags "-linkmode=external -X main.version=v$pkgver" -o dirt .
    
      38}
    
      39
    
      40check() {
    
      41  cd "$pkgname-$pkgver"
    
      42  export GOPATH="$srcdir/gopath"
    
      43  export GOFLAGS='-mod=readonly -modcacherw'
    
      44  go test ./...
    
      45}
    
      46
    
      47package() {
    
      48  cd "$pkgname-$pkgver"
    
      49  install -Dm755 dirt -t "$pkgdir/usr/bin/"
    
      50  install -Dm644 README.md CHANGELOG.md -t "$pkgdir/usr/share/doc/$pkgname/"
    
      51}
    
      52

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-19 01:23:43	Low	1