disc-image-studio

LOW

maintainer agony4001 0 votes scanned 2026-11-02 22:03:11.184944

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: agony <27015 at riseup dot net>
    
      2
    
      3pkgname=disc-image-studio
    
      4pkgver=1.3.6
    
      5pkgrel=1
    
      6pkgdesc='Generate CD, DVD and Blu-ray images that show a picture on the burned disc'
    
      7arch=('x86_64')
    
      8url='https://github.com/JiaFeiMiao-K-Cat/DiscImageStudio'
    
      9license=('GPL-3.0-or-later')
    
      10depends=('dotnet-runtime-10.0' 'glibc' 'libgcc' 'libstdc++')
    
      11makedepends=('dotnet-sdk-10.0')
    
      12options=('!debug')
    
      13source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz")
    
      14sha256sums=('34679c919067eef46f3976a77736986c5933961d90ac2770070dba474f7490eb')
    
      15
    
      16_project=src/DiscImageStudio.Cli/DiscImageStudio.Cli.csproj
    
      17
    
      18_dotnet_env() {
    
      19  export HOME="${srcdir}/home"
    
      20  export DOTNET_CLI_TELEMETRY_OPTOUT=1
    
      21  export DOTNET_GENERATE_ASPNET_CERTIFICATE=false
    
      22  export DOTNET_NOLOGO=1
    
      23  export DOTNET_SKIP_WORKLOAD_INTEGRITY_CHECK=1
    
      24  mkdir -p "${HOME}"
    
      25}
    
      26
    
      27prepare() {
    
      28  cd "DiscImageStudio-${pkgver}"
    
      29  _dotnet_env
    
      30  dotnet restore "${_project}" --disable-build-servers
    
      31}
    
      32
    
      33build() {
    
      34  cd "DiscImageStudio-${pkgver}"
    
      35  _dotnet_env
    
      36  dotnet publish "${_project}" \
    
      37    --no-restore \
    
      38    --disable-build-servers \
    
      39    --configuration Release \
    
      40    --self-contained false \
    
      41    --output "${srcdir}/publish" \
    
      42    -p:DebugType=none \
    
      43    -p:DebugSymbols=false
    
      44}
    
      45
    
      46check() {
    
      47  "${srcdir}/publish/${pkgname}" selftest
    
      48}
    
      49
    
      50package() {
    
      51  install -d "${pkgdir}/usr/lib/${pkgname}" "${pkgdir}/usr/bin"
    
      52  cp -a "${srcdir}/publish/." "${pkgdir}/usr/lib/${pkgname}/"
    
      53  ln -s "/usr/lib/${pkgname}/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
    
      54  install -Dm644 "DiscImageStudio-${pkgver}/THIRD-PARTY-NOTICES.txt" -t "${pkgdir}/usr/share/doc/${pkgname}"
    
      55}
    
      56

Scan history

Scanned at (UTC)	Severity	Rules
2026-11-02 22:03:11	Low	1