env0-cli-bin

LOW

maintainer dcelasun 0 votes scanned 2026-10-06 12:02:18.455551

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: D. Can Celasun <can[at]dcc[dot]im>
    
      2
    
      3pkgname=env0-cli-bin
    
      4pkgver=2.6.0
    
      5pkgrel=1
    
      6pkgdesc="The env0 command-line interface"
    
      7arch=('x86_64' 'aarch64')
    
      8url="https://www.env0.com"
    
      9license=('MIT')
    
      10# Statically linked Go binary, already stripped upstream
    
      11options=(!strip)
    
      12provides=('env0-cli')
    
      13conflicts=('env0-cli')
    
      14
    
      15source_x86_64=("${pkgname}-${pkgver}-x86_64.tgz::https://registry.npmjs.org/@env0/cli-linux-x64/-/cli-linux-x64-${pkgver}.tgz")
    
      16source_aarch64=("${pkgname}-${pkgver}-aarch64.tgz::https://registry.npmjs.org/@env0/cli-linux-arm64/-/cli-linux-arm64-${pkgver}.tgz")
    
      17sha256sums_x86_64=('85828d8e4745cd5f8af2c55e698834de820cc27bf6f02510ae22394ac3240647')
    
      18sha256sums_aarch64=('828d1ab4105b2143015056732bed0404db8ac653b35ab3b6271e62d03fffa0b8')
    
      19
    
      20build() {
    
      21  cd "${srcdir}/package"
    
      22
    
      23  # the binary writes a config file on every run, keep it inside srcdir
    
      24  export HOME="${srcdir}" XDG_CONFIG_HOME="${srcdir}/.config"
    
      25  for _shell in bash zsh fish; do
    
      26    ./bin/env0 completion "${_shell}" > "env0.${_shell}"
    
      27  done
    
      28}
    
      29
    
      30package() {
    
      31  cd "${srcdir}/package"
    
      32
    
      33  # binary
    
      34  install -Dm755 bin/env0 "${pkgdir}/usr/bin/env0"
    
      35
    
      36  # shell completions
    
      37  install -Dm644 env0.bash "${pkgdir}/usr/share/bash-completion/completions/env0"
    
      38  install -Dm644 env0.zsh "${pkgdir}/usr/share/zsh/site-functions/_env0"
    
      39  install -Dm644 env0.fish "${pkgdir}/usr/share/fish/vendor_completions.d/env0.fish"
    
      40
    
      41  # license
    
      42  install -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE
    
      43}
    
      44

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-06 12:02:18	Low	1