fastpotify-bin

LOW

maintainer crmne 0 votes scanned 2026-08-30 09:42:21.949430

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Carmine Paolino <carmine@paolino.me>
    
      2pkgname=fastpotify-bin
    
      3pkgver=0.3.0
    
      4pkgrel=1
    
      5pkgdesc="Fast native Spotify client with local playback and Spotify Connect"
    
      6arch=('x86_64' 'aarch64')
    
      7url="https://github.com/crmne/fastpotify"
    
      8license=('MIT')
    
      9install="${pkgname}.install"
    
      10# alsa-lib and libpulse are linked directly; the rest are dlopened by winit
    
      11# and glutin at startup, and this is a GUI-only application, so all of them
    
      12# have to be there for it to run at all.
    
      13depends=('alsa-lib' 'libpulse' 'libglvnd' 'libxkbcommon' 'wayland' 'libx11')
    
      14optdepends=('libxkbcommon-x11: keyboard handling in X11 sessions'
    
      15            'pipewire-pulse: PipeWire as the PulseAudio server')
    
      16provides=('fastpotify')
    
      17conflicts=('fastpotify' 'fastpotify-git')
    
      18options=('!debug' '!strip')
    
      19_repo="https://github.com/crmne/fastpotify"
    
      20source_x86_64=("${_repo}/releases/download/v${pkgver}/fastpotify-v${pkgver}-x86_64-unknown-linux-gnu.tar.gz")
    
      21source_aarch64=("${_repo}/releases/download/v${pkgver}/fastpotify-v${pkgver}-aarch64-unknown-linux-gnu.tar.gz")
    
      22sha256sums_x86_64=('a92bddb481c039e49e7087a81b86f5f52f9cad35c4b0599055e4e5ff4100dd0e')
    
      23sha256sums_aarch64=('9dd4f65dc1f41fef5ccf2f55c5e6ae828f4bbc70bb81f9d5989454e6bc9755ec')
    
      24
    
      25package() {
    
      26  local target
    
      27  case "$CARCH" in
    
      28    x86_64) target="x86_64-unknown-linux-gnu" ;;
    
      29    aarch64) target="aarch64-unknown-linux-gnu" ;;
    
      30  esac
    
      31  local dir="${srcdir}/fastpotify-v${pkgver}-${target}"
    
      32
    
      33  install -Dm755 "${dir}/fastpotify" "${pkgdir}/usr/bin/fastpotify"
    
      34  install -Dm644 "${dir}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    
      35  install -Dm644 "${dir}/README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
    
      36  install -Dm644 "${dir}/packaging/applications/fastpotify.desktop" \
    
      37    "${pkgdir}/usr/share/applications/fastpotify.desktop"
    
      38  install -Dm644 "${dir}/packaging/icons/fastpotify.svg" \
    
      39    "${pkgdir}/usr/share/icons/hicolor/scalable/apps/fastpotify.svg"
    
      40}
    
      41

Scan history

Scanned at (UTC)	Severity	Rules
2026-08-30 09:42:21	Low	1