fastsapp-git

LOW

maintainer crmne 0 votes scanned 2026-08-29 17:40:20.882297

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Carmine Paolino <carmine@paolino.me>
    
      2pkgname=fastsapp-git
    
      3pkgver=0.1.0.r0.58782a1
    
      4pkgrel=1
    
      5pkgdesc="Fast native WhatsApp client built with Rust and egui"
    
      6arch=('x86_64' 'aarch64')
    
      7url="https://github.com/crmne/fastsapp"
    
      8license=('MIT')
    
      9install="${pkgname}.install"
    
      10depends=('libglvnd' 'libxkbcommon' 'wayland' 'libx11')
    
      11makedepends=('git' 'cargo')
    
      12optdepends=('libxkbcommon-x11: keyboard handling in X11 sessions'
    
      13            'noto-fonts-emoji: colour emoji in messages and reactions'
    
      14            'ffmpeg: playing GIFs'
    
      15            'xdg-desktop-portal: the file picker for attachments')
    
      16provides=('fastsapp')
    
      17conflicts=('fastsapp')
    
      18# !lto because ring compiles its own C and Arch's default CFLAGS put LTO
    
      19# objects in the archive, which lld then cannot resolve: the link fails on
    
      20# undefined ring_core_* symbols. The stable package is prebuilt and never
    
      21# meets this.
    
      22options=('!debug' '!lto')
    
      23source=("${pkgname}::git+https://github.com/crmne/fastsapp.git")
    
      24sha256sums=('SKIP')
    
      25
    
      26pkgver() {
    
      27  cd "${srcdir}/${pkgname}"
    
      28  git describe --long --tags --abbrev=7 | sed 's/^v//;s/\-/.r/;s/\-g/./'
    
      29}
    
      30
    
      31prepare() {
    
      32  cd "${srcdir}/${pkgname}"
    
      33  export RUSTUP_TOOLCHAIN=stable
    
      34  # whatsapp-rust is a git dependency pinned to a commit; the lockfile
    
      35  # names it, so this fetches it along with everything else.
    
      36  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
    
      37}
    
      38
    
      39build() {
    
      40  cd "${srcdir}/${pkgname}"
    
      41  export RUSTUP_TOOLCHAIN=stable
    
      42  export CARGO_TARGET_DIR=target
    
      43  # Generated bindings inside glutin carry the path they were built at, which
    
      44  # ends up in the binary and makes makepkg warn about a reference to $srcdir.
    
      45  # Appended rather than assigned, so the distro's own flags survive.
    
      46  export RUSTFLAGS="${RUSTFLAGS:-} --remap-path-prefix=${srcdir}=/"
    
      47  cargo build --frozen --release
    
      48}
    
      49
    
      50check() {
    
      51  cd "${srcdir}/${pkgname}"
    
      52  export RUSTUP_TOOLCHAIN=stable
    
      53  # The demo feature carries the headless layout test of every screen,
    
      54  # which needs no display and talks to nothing.
    
      55  cargo test --frozen --features demo
    
      56}
    
      57
    
      58package() {
    
      59  cd "${srcdir}/${pkgname}"
    
      60
    
      61  install -Dm755 "target/release/fastsapp" "${pkgdir}/usr/bin/fastsapp"
    
      62  install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    
      63  install -Dm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
    
      64  install -Dm644 "packaging/applications/fastsapp.desktop" \
    
      65    "${pkgdir}/usr/share/applications/fastsapp.desktop"
    
      66  install -Dm644 "packaging/icons/fastsapp.svg" \
    
      67    "${pkgdir}/usr/share/icons/hicolor/scalable/apps/fastsapp.svg"
    
      68}
    
      69

Scan history

Scanned at (UTC)	Severity	Rules
2026-08-29 17:40:20	Low	1