filee-bin

LOW

maintainer Felitendo 0 votes scanned 2026-10-22 07:34:22.999679

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Felitendo
    
      2# This PKGBUILD is updated automatically:
    
      3# https://github.com/Felitendo/PKGBUILDS
    
      4
    
      5pkgname=filee-bin
    
      6pkgver=2.0.0
    
      7pkgrel=1
    
      8pkgdesc="Offline file converter for images, PDF, Office, HWP, video, audio, e-books and archives (upstream binary)"
    
      9arch=('x86_64' 'aarch64')
    
      10url="https://github.com/KnifeLemon/Filee"
    
      11license=('MIT')
    
      12# The bundle carries its own .NET runtime. These are the system libraries it
    
      13# still loads, as listed in upstream's INSTALL.txt.
    
      14depends=('glibc' 'gcc-libs' 'icu' 'openssl' 'krb5' 'zlib' 'fontconfig' 'freetype2'
    
      15         'libx11' 'libice' 'libsm' 'libxrandr' 'libxkbcommon' 'libxi' 'libxtst' 'libxt'
    
      16         'libinput' 'systemd-libs' 'wayland' 'hicolor-icon-theme')
    
      17# Filee cannot download LibreOffice and Ghostscript on Linux. The others it
    
      18# can download itself, but it uses a system copy when there is one.
    
      19optdepends=('libreoffice: Office documents'
    
      20            'ghostscript: PostScript and PDF compression'
    
      21            'ffmpeg: video and audio'
    
      22            'pandoc-cli: more document formats'
    
      23            'calibre: e-books'
    
      24            'noto-fonts-cjk: Korean, Chinese and Japanese text')
    
      25provides=('filee')
    
      26conflicts=('filee')
    
      27options=('!strip' '!debug')
    
      28
    
      29source=("com.filee.app.desktop")
    
      30sha256sums=('7924b339c9845b737fc76dc5f779f6d4d63a606990fcccfa40052d4e5a46b596')
    
      31
    
      32source_x86_64=("https://github.com/KnifeLemon/Filee/releases/download/v${pkgver}/Filee-${pkgver}-linux-x64.tar.gz")
    
      33sha256sums_x86_64=('e34a6f9464fac3af74dd646af54d7a75cffacb064fbe11d98701a874e68a170a')
    
      34
    
      35source_aarch64=("https://github.com/KnifeLemon/Filee/releases/download/v${pkgver}/Filee-${pkgver}-linux-arm64.tar.gz")
    
      36sha256sums_aarch64=('271271caa70df3cd675e73cde3ae72258882489d405a9331e425bb86fc7936d1')
    
      37
    
      38package() {
    
      39  local _dir="$srcdir/Filee-${pkgver}-linux-x64"
    
      40  [[ $CARCH == aarch64 ]] && _dir="$srcdir/Filee-${pkgver}-linux-arm64"
    
      41
    
      42  # upstream's self-contained bundle, without its scripts that copy it into
    
      43  # the home directory
    
      44  install -d "$pkgdir/opt/filee"
    
      45  cp -a "$_dir/." "$pkgdir/opt/filee/"
    
      46  rm "$pkgdir/opt/filee/"{install,uninstall}.sh
    
      47
    
      48  # same command name as upstream's install.sh gives the CLI
    
      49  install -d "$pkgdir/usr/bin"
    
      50  ln -s /opt/filee/filee-cli "$pkgdir/usr/bin/filee"
    
      51
    
      52  install -Dm644 "$srcdir/com.filee.app.desktop" -t "$pkgdir/usr/share/applications"
    
      53  install -Dm644 "$_dir/filee.png" "$pkgdir/usr/share/icons/hicolor/512x512/apps/filee.png"
    
      54
    
      55  # KWin script for the experimental Wayland gesture, so Plasma users can
    
      56  # turn it on in System Settings
    
      57  install -d "$pkgdir/usr/share/kwin/scripts"
    
      58  cp -r "$_dir/kwin/filee-donut" "$pkgdir/usr/share/kwin/scripts/"
    
      59
    
      60  install -Dm644 "$_dir/LICENSE" "$_dir/THIRD-PARTY-NOTICES.md" \
    
      61    -t "$pkgdir/usr/share/licenses/$pkgname"
    
      62}
    
      63

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-22 07:34:22	Low	1