flow5

maintainer dlblv · 0 votes · scanned 2026-08-18 07:39:23.787586

LOW

Why flagged Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

LOW Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: dlblv <mrdolbilov@gmail.com>
    
      2pkgname=flow5
    
      3pkgver=7.57
    
      4pkgrel=1
    
      5pkgdesc='Potential flow solver with built-in pre- and post-processing for wings, planes, hydrofoils and sails (successor to xflr5)'
    
      6arch=('x86_64')
    
      7url='https://flow5.tech'
    
      8license=('GPL-3.0-or-later')
    
      9depends=('qt6-base' 'opencascade' 'openblas' 'gmsh' 'gcc-libs' 'glibc'
    
      10         'hicolor-icon-theme')
    
      11makedepends=('qt6-tools')
    
      12provides=('libXFoil.so' 'libflow5-lib.so' 'libflow5-io-lib.so')
    
      13source=("$pkgname-$pkgver.tar.gz::https://github.com/techwinder/flow5/archive/refs/tags/v$pkgver.tar.gz")
    
      14sha256sums=('1dfcb4e7898b4d94a2b784ad5139aa09763a5faa0e3481243608c956805f9a2c')
    
      15
    
      16prepare() {
    
      17	cd "$srcdir/$pkgname-$pkgver"
    
      18
    
      19	# Arch's openblas ships libopenblas.so only; openblasp is a Fedora-only
    
      20	# name for the pthreads build.
    
      21	sed -i 's/-lopenblasp/-lopenblas/' flow5-app/flow5-app.pro flow5-lib/flow5-lib.pro
    
      22
    
      23	# The subdirs project declares no inter-target dependencies, so `make -j`
    
      24	# can try to link flow5-app before its libraries exist.
    
      25	printf '\nCONFIG += ordered\n' >>flow5.pro
    
      26
    
      27	# Runtime translation lookup is hardcoded to the /usr/local prefix.
    
      28	sed -i 's|"/usr/local/share/flow5/translations/"|"/usr/share/flow5/translations/"|' \
    
      29		flow5-app/globals/flow5.cpp
    
      30
    
      31	# Point the desktop entry at the packaged paths. Version= is the Desktop
    
      32	# Entry spec version, not the application version.
    
      33	sed -e 's|^Exec=.*|Exec=flow5|' \
    
      34	    -e 's|^Icon=.*|Icon=flow5|' \
    
      35	    -e 's|^Version=.*|Version=1.5|' \
    
      36	    -i meta/linux/flow5.desktop
    
      37}
    
      38
    
      39build() {
    
      40	cd "$srcdir/$pkgname-$pkgver"
    
      41
    
      42	# qmake only emits the translations install rule for .qm files that exist
    
      43	# when it runs, so compile them first.
    
      44	/usr/lib/qt6/bin/lrelease meta/translations/*.ts
    
      45
    
      46	# Built in-tree: the .pro files pin DESTDIR/OBJECTS_DIR to the source dirs
    
      47	# and resolve sibling libraries through relative -L paths.
    
      48	qmake6 \
    
      49		PREFIX=/usr \
    
      50		CONFIG+=release \
    
      51		QMAKE_CFLAGS_RELEASE="$CFLAGS" \
    
      52		QMAKE_CXXFLAGS_RELEASE="$CXXFLAGS" \
    
      53		QMAKE_LFLAGS_RELEASE="$LDFLAGS" \
    
      54		flow5.pro
    
      55	make
    
      56}
    
      57
    
      58package() {
    
      59	cd "$srcdir/$pkgname-$pkgver"
    
      60
    
      61	# Installs bin/flow5, the flow5/XFoil shared libraries and their API
    
      62	# headers, share/flow5/flow5.png and the translations.
    
      63	make INSTALL_ROOT="$pkgdir" install
    
      64
    
      65	install -Dm644 meta/linux/flow5.desktop \
    
      66		"$pkgdir/usr/share/applications/flow5.desktop"
    
      67	install -Dm644 meta/res/flow5.png \
    
      68		"$pkgdir/usr/share/icons/hicolor/128x128/apps/flow5.png"
    
      69	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      70}
    
      71

Scan history

Scanned at (UTC)	Severity	Rules
2026-08-18 07:39:23	LOW	1