fomalhaut-lock

LOW

maintainer fu050409 0 votes scanned 2026-08-19 17:42:05.760176

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: 苏向夜 <fu050409@163.com>
    
      2# SPDX-FileCopyrightText: 2026 Fomalhaut contributors
    
      3# SPDX-License-Identifier: 0BSD
    
      4
    
      5pkgname=fomalhaut-lock
    
      6_upstream_name=fomalhaut
    
      7_upstream_ver=0.1.0-alpha.2
    
      8_source_ref=71c0a28a60690550a4904a419962a150734e0090
    
      9pkgver=0.1.0.alpha.2
    
      10pkgrel=1
    
      11pkgdesc='WebKitGTK Wayland session locker'
    
      12arch=('x86_64')
    
      13url='https://github.com/noctisynth/fomalhaut'
    
      14license=('AGPL-3.0-only')
    
      15depends=(
    
      16  'glib2'
    
      17  'glibc'
    
      18  'gtk4'
    
      19  'gtk4-layer-shell'
    
      20  'libgcc'
    
      21  'libsoup3'
    
      22  'pam'
    
      23  'webkitgtk-6.0'
    
      24)
    
      25optdepends=('accountsservice: current user avatar')
    
      26makedepends=('cargo' 'clang')
    
      27backup=('etc/pam.d/fomalhaut-lock')
    
      28source=("${_upstream_name}-${_source_ref}.tar.gz::${url}/archive/${_source_ref}.tar.gz")
    
      29sha256sums=('8e732f4d1b9490ea3104506c4197f763036896c76b5daf2258436d64d234baac')
    
      30
    
      31_source_dir="${_upstream_name}-${_source_ref}"
    
      32
    
      33prepare() {
    
      34  cd "${_source_dir}"
    
      35  cargo fetch --locked
    
      36}
    
      37
    
      38build() {
    
      39  cd "${_source_dir}"
    
      40  CARGO_TARGET_DIR=target cargo build --frozen --release --package fomalhaut-lock
    
      41}
    
      42
    
      43check() {
    
      44  cd "${_source_dir}"
    
      45  CARGO_TARGET_DIR=target cargo test --frozen \
    
      46    --package fomalhaut-lock --package fomalhaut-logind --package fomalhaut-pam \
    
      47    --package fomalhaut-user --all-targets
    
      48}
    
      49
    
      50package() {
    
      51  cd "${_source_dir}"
    
      52
    
      53  sed 's|@FOMALHAUT_''LOCK@|/usr/bin/fomalhaut-lock|' \
    
      54    packaging/systemd/fomalhaut-lock.service.in >target/fomalhaut-lock.service
    
      55  install -Dm755 target/release/fomalhaut-lock "${pkgdir}/usr/bin/fomalhaut-lock"
    
      56  install -Dm644 packaging/pam/fomalhaut-lock \
    
      57    "${pkgdir}/etc/pam.d/fomalhaut-lock"
    
      58  install -Dm644 target/fomalhaut-lock.service \
    
      59    "${pkgdir}/usr/lib/systemd/user/fomalhaut-lock.service"
    
      60  install -Dm644 packaging/idle/swayidle.conf \
    
      61    "${pkgdir}/usr/share/doc/${pkgname}/swayidle.conf"
    
      62  install -Dm644 packaging/niri/fomalhaut-lock.kdl \
    
      63    "${pkgdir}/usr/share/doc/${pkgname}/niri.kdl"
    
      64  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    
      65  install -Dm644 docs/CONFIGURATION.md \
    
      66    "${pkgdir}/usr/share/doc/${pkgname}/configuration.md"
    
      67}
    
      68

Changes since previous scan

--- PKGBUILD @ 2026-08-18 00:03
+++ PKGBUILD @ 2026-08-19 17:42
@@ -4,9 +4,9 @@
 
 pkgname=fomalhaut-lock
 _upstream_name=fomalhaut
-_upstream_ver=0.1.0-alpha.1
-_source_ref=2300034dcfac72e13c8475d992fa9c75aac933ed
-pkgver=0.1.0.alpha.1
+_upstream_ver=0.1.0-alpha.2
+_source_ref=71c0a28a60690550a4904a419962a150734e0090
+pkgver=0.1.0.alpha.2
 pkgrel=1
 pkgdesc='WebKitGTK Wayland session locker'
 arch=('x86_64')
@@ -26,7 +26,7 @@
 makedepends=('cargo' 'clang')
 backup=('etc/pam.d/fomalhaut-lock')
 source=("${_upstream_name}-${_source_ref}.tar.gz::${url}/archive/${_source_ref}.tar.gz")
-sha256sums=('b50fccd46264d6d3e3f2cd5c5408df007a1fc6eb6949102b3c2a36a282488277')
+sha256sums=('8e732f4d1b9490ea3104506c4197f763036896c76b5daf2258436d64d234baac')
 
 _source_dir="${_upstream_name}-${_source_ref}"
 

Scan history

Scanned at (UTC)	Severity	Rules
2026-08-19 17:42:05	Low	1
2026-08-18 00:03:42	Clean	2
2026-08-17 11:35:53	Low	1