freshgram-git

LOW

maintainer Snowy-Fluffy 1 votes scanned 2026-10-19 01:23:43.518710

View on AUR

Why flagged

The package builds from source using git repositories with SKIP'd checksums, which is common for -git packages, and depends on standard system libraries and official project sources; the flagged low votes and recent upload are metadata concerns, not security risks.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Low AI review llm_review

An AI model (qwen/qwen3-235b-a22b-2507) reviewed this and agrees it is LOW (confidence 95%): The package builds from source using git repositories with SKIP'd checksums, which is common for -git packages, and depends on standard system libraries and official project sources; the flagged low votes and recent upload are metadata concerns, not security risks.

PKGBUILD

      1# Maintainer: Snowy-Fluffy <snowy.lnnk@gmail.com>
    
      2
    
      3# prevent excessive memory usage
    
      4export DEBUG_CFLAGS="-g1"
    
      5export DEBUG_CXXFLAGS="-g1"
    
      6
    
      7: ${_branch:=main}
    
      8: ${_commit=}
    
      9
    
      10_pkgname=freshgram
    
      11pkgname="$_pkgname-git"
    
      12pkgver=7.5.5.r85.g26d2291
    
      13pkgrel=1
    
      14pkgdesc='Breaking ToS Telegram Desktop fork with a lot of security features, all AyuGram features, and a lot of design styles (git version)'
    
      15arch=('x86_64')
    
      16url='https://github.com/Snowy-Fluffy/freshGram'
    
      17license=('GPL-3.0-or-later WITH OpenSSL-exception')
    
      18depends=(
    
      19	'abseil-cpp'
    
      20	'ada'
    
      21	'cairo'
    
      22	'ffmpeg'
    
      23	'fontconfig'
    
      24	'glib2'
    
      25	'glibc'
    
      26	'hicolor-icon-theme'
    
      27	'hunspell'
    
      28	'kcoreaddons'
    
      29	'libavif'
    
      30	'libfido2'
    
      31	'libgcc'
    
      32	'libheif'
    
      33	'libjpeg-turbo'
    
      34	'libjxl'
    
      35	'libpipewire'
    
      36	'libsrtp'
    
      37	'libstdc++'
    
      38	'libvpx'
    
      39	'libx11'
    
      40	'libxcb'
    
      41	'libxcomposite'
    
      42	'libxdamage'
    
      43	'libxext'
    
      44	'libxfixes'
    
      45	'libxkbcommon'
    
      46	'libxrandr'
    
      47	'libxtst'
    
      48	'lz4'
    
      49	'minizip'
    
      50	'openal'
    
      51	'openh264'
    
      52	'openssl'
    
      53	'opus'
    
      54	'pango'
    
      55	'pipewire'
    
      56	'qt6-base'
    
      57	'qt6-declarative'
    
      58	'qt6-imageformats'
    
      59	'qt6-svg'
    
      60	'qt6-wayland'
    
      61	'rnnoise'
    
      62	'tlottie'
    
      63	'xxhash'
    
      64	'zlib'
    
      65)
    
      66makedepends=(
    
      67	'boost'
    
      68	'boost-libs'
    
      69	'cmake'
    
      70	'git'
    
      71	'glib2-devel'
    
      72	'gobject-introspection'
    
      73	'gperf'
    
      74	'libtg_owt'
    
      75	'microsoft-gsl'
    
      76	'ninja'
    
      77	'python'
    
      78	'qt6-shadertools'
    
      79	'range-v3'
    
      80	'tl-expected'
    
      81	'vulkan-headers'
    
      82)
    
      83optdepends=(
    
      84	'webkit2gtk-4.1: embedded browser features provided by webkit2gtk-4.1 (gtk3)'
    
      85	'webkitgtk-6.0: embedded browser features provided by webkitgtk-6.0 (gtk4)'
    
      86	'xdg-desktop-portal: desktop integration'
    
      87)
    
      88provides=("$_pkgname=${pkgver%%.r*}")
    
      89conflicts=("$_pkgname" "$_pkgname-bin")
    
      90options=('!lto')
    
      91
    
      92_pkgsrc=freshGram
    
      93_pkgsrc_td=telegram-tdlib
    
      94# The commit of tdlib with the tde2e library that the project builds against,
    
      95# see Telegram/build/docker/centos_env/Dockerfile.
    
      96_td_commit=51743dfd01dff6179e2d8f7095729caa4e2222e9
    
      97
    
      98source=(
    
      99	"$_pkgsrc"::"git+$url.git${_commit:+#commit=$_commit}${_commit:-${_branch:+#branch=$_branch}}"
    
      100	"$_pkgsrc_td"::"git+https://github.com/tdlib/td.git#commit=$_td_commit"
    
      101)
    
      102sha256sums=('SKIP'
    
      103            'SKIP')
    
      104
    
      105prepare() {
    
      106	cd "$_pkgsrc"
    
      107
    
      108	# These come from the system packages.
    
      109	local lib
    
      110	for lib in GSL expected hunspell kcoreaddons libfido2 lz4 range-v3 xxHash; do
    
      111		git submodule deinit -f "Telegram/ThirdParty/$lib" 2>/dev/null || true
    
      112		git config "submodule.Telegram/ThirdParty/$lib.update" none
    
      113	done
    
      114	git submodule update --init --recursive --depth=1
    
      115}
    
      116
    
      117pkgver() {
    
      118	cd "$_pkgsrc"
    
      119	printf '%s.r%s.g%s' \
    
      120		"$(awk '/^AppVersionStr /{print $2}' Telegram/build/version)" \
    
      121		"$(git rev-list --count HEAD)" \
    
      122		"$(git rev-parse --short=7 HEAD)"
    
      123}
    
      124
    
      125build() {
    
      126	cmake -S "$_pkgsrc_td" -B build_tde2e \
    
      127		-G Ninja \
    
      128		-DCMAKE_BUILD_TYPE=None \
    
      129		-DCMAKE_INSTALL_PREFIX=/usr \
    
      130		-DTD_E2E_ONLY=ON \
    
      131		-DBUILD_SHARED_LIBS=OFF \
    
      132		-DBUILD_TESTING=OFF \
    
      133		-Wno-dev
    
      134	cmake --build build_tde2e
    
      135	DESTDIR="$srcdir/deps" cmake --install build_tde2e
    
      136
    
      137	# The official API key that Telegram uses for its snap builds, the same one
    
      138	# the telegram-desktop package in the official repositories uses:
    
      139	# https://github.com/telegramdesktop/tdesktop/blob/8fab9167beb2407c1153930ed03a4badd0c2b59f/snap/snapcraft.yaml#L87-L88
    
      140	cmake -S "$_pkgsrc" -B build \
    
      141		-G Ninja \
    
      142		-DCMAKE_BUILD_TYPE=None \
    
      143		-DCMAKE_INSTALL_PREFIX=/usr \
    
      144		-DCMAKE_PREFIX_PATH="$srcdir/deps/usr" \
    
      145		-Dtde2e_DIR="$srcdir/deps/usr/lib/cmake/tde2e" \
    
      146		-DDESKTOP_APP_DISABLE_AUTOUPDATE=ON \
    
      147		-DDESKTOP_APP_DISABLE_CRASH_REPORTS=ON \
    
      148		-DTDESKTOP_API_ID=611335 \
    
      149		-DTDESKTOP_API_HASH=d524b414d21f4d37f08684c1df41ac9c \
    
      150		-Wno-dev
    
      151	cmake --build build
    
      152}
    
      153
    
      154package() {
    
      155	DESTDIR="$pkgdir" cmake --install build
    
      156	install -Dm644 "$_pkgsrc/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      157}
    
      158

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-19 01:23:43	Low	2