ghidra-extension-kuna-bin

LOW

maintainer robertfoster 0 votes base kuna-bin scanned 2026-09-25 19:13:08.013724

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: robertfoster
    
      2pkgbase=kuna-bin
    
      3pkgname=("${pkgbase}" "ghidra-extension-${pkgbase}")
    
      4_pkgname="${pkgbase%-bin}"
    
      5pkgver=1.585 # renovate: datasource=github-releases depName=Noelo-Lab/kuna
    
      6# Ghidra release the extension zip is built against; it is part of the asset name
    
      7_ghidraver=12.1.2
    
      8pkgrel=1
    
      9pkgdesc="Agent-first decompiler, ported from Ghidra to Rust, designed to be refined by other agents"
    
      10arch=('x86_64' 'aarch64')
    
      11url="https://github.com/Noelo-Lab/kuna"
    
      12license=('Apache-2.0')
    
      13options=('!strip')
    
      14_dl="${url}/releases/download/v${pkgver}/${_pkgname}-v${pkgver}"
    
      15source=("${_dl}-specs.tar.gz"
    
      16  "${_dl}-KunaDecompiler-ghidra_${_ghidraver}.zip")
    
      17source_x86_64=("${_dl}-linux-x86_64.tar.gz")
    
      18source_aarch64=("${_dl}-linux-arm64.tar.gz")
    
      19sha256sums=('05d792f41a4fb83edbc359afc6ef93e71ceaafdc3e7d232a7b3a9960c225211b'
    
      20  '79e31cee3397a69696bd02ee08a4c52565ee1fbfa121508e79571898af6a2d20')
    
      21sha256sums_x86_64=('5cdf45d3c177e5ff86013095577ab9ee8866718288b76449cc02649cb20382ed')
    
      22sha256sums_aarch64=('b84bb0abcca98e721f8198520b0e931e998e4f4db0a9b00a9432e21c5f64a85b')
    
      23
    
      24package_kuna-bin() {
    
      25  depends=('glibc' 'libgcc')
    
      26  optdepends=("ghidra-extension-${pkgbase}: kuna as the decompiler core of the Ghidra GUI")
    
      27  provides=("${_pkgname}")
    
      28  conflicts=("${_pkgname}" "${_pkgname}-git")
    
      29
    
      30  local _dist="${srcdir}/${_pkgname}-v${pkgver}-linux-${CARCH/aarch64/arm64}"
    
      31
    
      32  # kuna finds decomp_dbg, slacomp and specs/ next to its symlink-resolved path
    
      33  install -Dm755 -t "${pkgdir}/usr/lib/${_pkgname}" \
    
      34    "${_dist}"/{kuna,decomp_dbg,slacomp}
    
      35  install -d "${pkgdir}/usr/bin"
    
      36  ln -s "/usr/lib/${_pkgname}/kuna" "${pkgdir}/usr/bin/kuna"
    
      37
    
      38  # compiled SLEIGH processor specs, vendored from Ghidra
    
      39  install -d "${pkgdir}/usr/share/${_pkgname}"
    
      40  cp -r --no-preserve=mode "${srcdir}/specs" "${pkgdir}/usr/share/${_pkgname}/"
    
      41  ln -s "/usr/share/${_pkgname}/specs" "${pkgdir}/usr/lib/${_pkgname}/specs"
    
      42
    
      43  install -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgbase}" \
    
      44    "${_dist}"/{LICENSE,NOTICE}
    
      45}
    
      46
    
      47package_ghidra-extension-kuna-bin() {
    
      48  pkgdesc="Ghidra extension running kuna as the native decompiler core behind the stock Ghidra GUI"
    
      49  depends=('ghidra' 'glibc' 'libgcc')
    
      50  provides=("ghidra-extension-${_pkgname}")
    
      51  conflicts=("ghidra-extension-${_pkgname}")
    
      52
    
      53  local _dist="${srcdir}/${_pkgname}-v${pkgver}-linux-${CARCH/aarch64/arm64}"
    
      54  local _os="linux_${CARCH/aarch64/arm_64}"
    
      55  local _ext="${pkgdir}/opt/ghidra/Ghidra/Extensions/KunaDecompiler"
    
      56
    
      57  # Ghidra loads modules in its installation Extensions/ dir for every user
    
      58  install -d "${_ext%/*}"
    
      59  cp -r "${srcdir}/KunaDecompiler" "${_ext%/*}/"
    
      60
    
      61  # keep only this platform's kuna_ghidra backend; build.sh and the os/ README
    
      62  # are from-source helpers
    
      63  find "${_ext}/os" -mindepth 1 -maxdepth 1 ! -name "${_os}" -exec rm -r {} +
    
      64  rm -f "${_ext}/build.sh" "${_ext}/os/${_os}/README.md"
    
      65
    
      66  install -Dm644 -t "${pkgdir}/usr/share/licenses/ghidra-extension-${pkgbase}" \
    
      67    "${_dist}"/{LICENSE,NOTICE}
    
      68}
    
      69

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-25 19:13:08	Low	1
2026-09-25 00:03:36	Clean	2
2026-09-24 19:44:16	Low	1