ghostunnel

LOW

maintainer agony4001 0 votes scanned 2026-11-04 16:07:14.930874

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: agony <27015 at riseup dot net>
    
      2
    
      3pkgname=ghostunnel
    
      4pkgver=1.11.5
    
      5pkgrel=1
    
      6pkgdesc='TLS proxy with mutual authentication for securing non-TLS services'
    
      7arch=('x86_64' 'aarch64')
    
      8url='https://github.com/ghostunnel/ghostunnel'
    
      9license=('Apache-2.0')
    
      10depends=('glibc')
    
      11makedepends=('go')
    
      12source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz")
    
      13sha256sums=('4e422caf02e8fc2082f749f56b37dd64133da0e288cebdfdde52be8537ead69a')
    
      14
    
      15build() {
    
      16  cd "${pkgname}-${pkgver}"
    
      17  export GOPATH="${srcdir}/gopath"
    
      18  export CGO_CPPFLAGS="${CPPFLAGS}"
    
      19  export CGO_CFLAGS="${CFLAGS}"
    
      20  export CGO_CXXFLAGS="${CXXFLAGS}"
    
      21  export CGO_LDFLAGS="${LDFLAGS}"
    
      22  export GOFLAGS='-buildmode=pie -trimpath -buildvcs=false -mod=vendor -modcacherw'
    
      23  go build -v -ldflags="-linkmode=external -X main.version=v${pkgver}" -o ghostunnel .
    
      24  ./ghostunnel --help-custom-man > ghostunnel.1
    
      25  ./ghostunnel --completion-script-bash > ghostunnel.bash
    
      26  ./ghostunnel --completion-script-zsh > ghostunnel.zsh
    
      27}
    
      28
    
      29check() {
    
      30  cd "${pkgname}-${pkgver}"
    
      31  export GOPATH="${srcdir}/gopath"
    
      32  export GOFLAGS='-buildvcs=false -mod=vendor -modcacherw'
    
      33  # The ACME tests write certmagic storage to XDG_DATA_HOME, ~/.local/share by default
    
      34  export XDG_DATA_HOME="${srcdir}/xdg-data"
    
      35  go test ./...
    
      36}
    
      37
    
      38package() {
    
      39  cd "${pkgname}-${pkgver}"
    
      40  install -Dm755 ghostunnel -t "${pkgdir}/usr/bin"
    
      41  install -Dm644 ghostunnel.1 -t "${pkgdir}/usr/share/man/man1"
    
      42  install -Dm644 ghostunnel.bash "${pkgdir}/usr/share/bash-completion/completions/ghostunnel"
    
      43  install -Dm644 ghostunnel.zsh "${pkgdir}/usr/share/zsh/site-functions/_ghostunnel"
    
      44}
    
      45

Scan history

Scanned at (UTC)	Severity	Rules
2026-11-04 16:07:14	Low	1