gnome-shell-extension-astra-monitor-git

LOW

maintainer nvidiahater 0 votes scanned 2026-10-17 00:21:55.226236

View on AUR

Why flagged

The package builds a GNOME Shell extension from its official Git repository; the low severity is due to few votes and recent upload, but the source is transparent and the build process is safe.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Low AI review llm_review

An AI model (qwen/qwen3-235b-a22b-2507) reviewed this and agrees it is LOW (confidence 95%): The package builds a GNOME Shell extension from its official Git repository; the low severity is due to few votes and recent upload, but the source is transparent and the build process is safe.

PKGBUILD

      1pkgname=gnome-shell-extension-astra-monitor-git
    
      2pkgver=43.r0.g90decfa
    
      3pkgrel=1
    
      4pkgdesc="Monitor CPU, GPU, memory, storage, network activity, and sensors in the GNOME panel"
    
      5arch=('any')
    
      6url="https://github.com/AstraExt/astra-monitor"
    
      7license=('GPL-3.0-or-later')
    
      8depends=('gnome-shell>=45' 'libadwaita' 'procps-ng')
    
      9makedepends=('gettext' 'git' 'typescript>=5.6')
    
      10optdepends=(
    
      11  'libgtop: Alternative system monitoring data source'
    
      12  'pciutils: PCI device information'
    
      13  'iw: Wireless network information'
    
      14  'wireless_tools: Alternative wireless network information'
    
      15  'nethogs: Network activity per process'
    
      16  'iotop: Disk activity per process'
    
      17  'amdgpu_top: AMD GPU monitoring'
    
      18  'nvidia-utils: NVIDIA GPU monitoring'
    
      19  'intel-gpu-tools: Intel GPU monitoring'
    
      20)
    
      21provides=("${pkgname%-git}")
    
      22conflicts=("${pkgname%-git}")
    
      23_uuid='monitor@astraext.github.io'
    
      24source=("astra-monitor::git+${url}.git#branch=main")
    
      25sha256sums=('SKIP')
    
      26
    
      27pkgver() {
    
      28  cd astra-monitor
    
      29  git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
    
      30}
    
      31
    
      32build() {
    
      33  cd astra-monitor
    
      34  # Transpile without upstream's development-only GIR type dependencies.
    
      35  tsc --noCheck --incremental false
    
      36  install -m644 metadata.json stylesheet.css build/
    
      37  cp -r icons schemas LICENSE build/
    
      38  gnome-extensions pack --force --podir=../po \
    
      39    --extra-source=src --extra-source=icons --extra-source=LICENSE build
    
      40}
    
      41
    
      42package() {
    
      43  local extension_dir="${pkgdir}/usr/share/gnome-shell/extensions/${_uuid}"
    
      44
    
      45  install -d "${extension_dir}"
    
      46  bsdtar -xf "astra-monitor/${_uuid}.shell-extension.zip" \
    
      47    -C "${extension_dir}" --no-same-owner
    
      48
    
      49  install -Dm644 \
    
      50    "${extension_dir}/schemas/org.gnome.shell.extensions.astra-monitor.gschema.xml" \
    
      51    -t "${pkgdir}/usr/share/glib-2.0/schemas/"
    
      52  rm -r "${extension_dir}/schemas"
    
      53
    
      54  install -Dm644 "${extension_dir}/LICENSE" \
    
      55    "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    
      56}
    
      57

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-17 00:21:55	Low	2
2026-10-16 00:12:47	Low	2
2026-10-15 00:28:05	Low	2
2026-10-14 00:06:47	Low	2
2026-10-13 00:23:45	Low	2
2026-10-12 05:12:20	Low	2