graphs1090-git

LOW

maintainer meijin 0 votes scanned 2026-09-03 21:54:41.624619

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Assaf Sapir <assaf AT sapir.io>
    
      2pkgname=graphs1090-git
    
      3pkgver=1.0.1.r462.g426c70c
    
      4pkgrel=1
    
      5pkgdesc="Graphs for dump1090: message rate, aircraft, range, signal, gain, CPU and temperature over time"
    
      6arch=('any')
    
      7url="https://github.com/wiedehopf/graphs1090"
    
      8license=('MIT')
    
      9depends=('bash' 'collectd' 'rrdtool' 'python' 'dump1090')
    
      10optdepends=('lighttpd: serve the web interface'
    
      11            'nginx: serve the web interface')
    
      12backup=('etc/default/graphs1090' 'etc/lighttpd/conf.d/graphs1090.conf')
    
      13install=graphs1090.install
    
      14source=("graphs1090::git+https://github.com/wiedehopf/graphs1090.git")
    
      15sha256sums=('SKIP')
    
      16
    
      17pkgver() {
    
      18  cd graphs1090
    
      19  printf '%s.r%s.g%s' "$(cat version)" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
    
      20}
    
      21
    
      22prepare() {
    
      23  cd graphs1090
    
      24  rm install.sh uninstall.sh tag.sh
    
      25  # Arch keeps collectd's config in /etc/collectd.conf; upstream's optional configs are not under git/ here
    
      26  grep -rl --exclude-dir=.git '/etc/collectd/collectd.conf' . | xargs sed -i 's?/etc/collectd/collectd.conf?/etc/collectd.conf?g'
    
      27  sed -i 's?/graphs1090/git/?/graphs1090/?' default
    
      28  sed -i "s|<!-- version -->| $(cat version)|" html/index.html
    
      29}
    
      30
    
      31package() {
    
      32  cd graphs1090
    
      33  install -d "$pkgdir/usr/share/graphs1090/data-symlink" "$pkgdir/var/lib/graphs1090/scatter"
    
      34  install -m755 *.sh "$pkgdir/usr/share/graphs1090/"
    
      35  install -m644 *.py dump1090.db malarky.conf collectd.conf hide_system-collectd.conf "$pkgdir/usr/share/graphs1090/"
    
      36  cp -r html "$pkgdir/usr/share/graphs1090/html"
    
      37  # collectd.conf reads stats.json from data-symlink/data/, which upstream points at the decoder
    
      38  ln -s /run/dump1090 "$pkgdir/usr/share/graphs1090/data-symlink/data"
    
      39  install -Dm644 default "$pkgdir/etc/default/graphs1090"
    
      40  install -Dm644 service.service "$pkgdir/usr/lib/systemd/system/graphs1090.service"
    
      41  install -Dm644 88-graphs1090.conf "$pkgdir/etc/lighttpd/conf.d/graphs1090.conf"
    
      42  install -Dm644 -t "$pkgdir/usr/share/doc/graphs1090" nginx-graphs1090.conf README.md
    
      43  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      44}
    
      45

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-03 21:54:41	Low	1