heatsync-tui

LOW

maintainer mellen9999 0 votes scanned 2026-08-25 21:28:32.222906

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: mellen <mellen@heatsync.org>
    
      2#
    
      3# Deliberately does NOT declare provides=('heatsync') or conflicts=('heatsync').
    
      4# An unrelated MIT project of the same name ships `heatsync-bin` on the AUR and
    
      5# that package claims both. Ours installs /usr/bin/heatsync-tui, so the two can
    
      6# sit on the same machine without pacman having to pick one.
    
      7
    
      8pkgname=heatsync-tui
    
      9pkgver=0.1.1
    
      10pkgrel=1
    
      11pkgdesc='heat-sorted live multichat in the terminal — twitch + kick, real emotes, vim keys'
    
      12arch=('x86_64' 'aarch64')
    
      13url='https://github.com/mellen9999/heatsync-tui'
    
      14license=('MIT')
    
      15# ring's C/asm objects break under makepkg's default LTO — undefined
    
      16# ring_core_* symbols at link. Standard fix for ring-dependent Rust crates.
    
      17options=('!lto')
    
      18depends=('gcc-libs' 'glibc')
    
      19makedepends=('cargo')
    
      20source=("$pkgname-$pkgver.tar.gz::https://static.crates.io/crates/$pkgname/$pkgname-$pkgver.crate")
    
      21sha256sums=('d360df7b8b82a1065c69f0fdc5cc97e1a291fb01b08913161314e8a8c489edbb')
    
      22
    
      23prepare() {
    
      24  cd "$pkgname-$pkgver"
    
      25  export RUSTUP_TOOLCHAIN=stable
    
      26  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
    
      27}
    
      28
    
      29build() {
    
      30  cd "$pkgname-$pkgver"
    
      31  export RUSTUP_TOOLCHAIN=stable
    
      32  export CARGO_TARGET_DIR=target
    
      33  cargo build --frozen --release --all-features
    
      34}
    
      35
    
      36check() {
    
      37  cd "$pkgname-$pkgver"
    
      38  export RUSTUP_TOOLCHAIN=stable
    
      39  cargo test --frozen --all-features
    
      40}
    
      41
    
      42package() {
    
      43  cd "$pkgname-$pkgver"
    
      44  install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/$pkgname"
    
      45  install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
    
      46  install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname/" README.md
    
      47}
    
      48

Scan history

Scanned at (UTC)	Severity	Rules
2026-08-25 21:28:32	Low	1