herakleo

LOW

maintainer Crstian 0 votes scanned 2026-10-28 21:50:44.871523

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Crstian <me@crstian.me>
    
      2#
    
      3# Built from a tarball of the repo: `just package-arch` locally (working tree)
    
      4# or the release workflow (the tagged commit). The AUR packages are in
    
      5# packaging/aur.
    
      6
    
      7pkgname=herakleo
    
      8pkgver=0.1.1
    
      9pkgrel=1
    
      10pkgdesc='Desktop IPTV player for M3U lists and Xtream Codes'
    
      11arch=('x86_64')
    
      12url='https://github.com/crstian19/herakleo'
    
      13license=('GPL-3.0-or-later')
    
      14# Wails v3: GTK 4 + webkitgtk-6.0 (scrolls at the monitor's refresh rate).
    
      15depends=(
    
      16  'webkitgtk-6.0'
    
      17  'gtk4'
    
      18  'libsoup3'
    
      19  'glib2'
    
      20  'hicolor-icon-theme'
    
      21  'glibc'
    
      22)
    
      23makedepends=(
    
      24  'go'
    
      25  'bun'
    
      26  'nodejs'
    
      27  'pkgconf'
    
      28)
    
      29optdepends=(
    
      30  'mpv: default video player'
    
      31  'vlc: alternative video player'
    
      32  'celluloid: alternative video player'
    
      33  'haruna: alternative video player'
    
      34)
    
      35# The package was called herakleo-wails while a second (Tauri) build existed.
    
      36provides=('herakleo-wails')
    
      37conflicts=('herakleo-wails')
    
      38replaces=('herakleo-wails')
    
      39# makepkg's LTO flags break cgo
    
      40options=('!lto' '!debug')
    
      41source=("herakleo-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
    
      42sha256sums=('4827fb5a13dedadc8201f16e4c0ae8b2bf78272f27037fa82a77729a2a6b2921')
    
      43
    
      44_goenv() {
    
      45  export GOPATH="$srcdir/gopath"
    
      46  # -buildvcs=false: the source may sit inside another user's git checkout (CI).
    
      47  export GOFLAGS='-buildmode=pie -trimpath -modcacherw -buildvcs=false'
    
      48  export CGO_ENABLED=1
    
      49  export CGO_CPPFLAGS="$CPPFLAGS"
    
      50  export CGO_CFLAGS="$CFLAGS -Wno-deprecated-declarations"
    
      51  export CGO_CXXFLAGS="$CXXFLAGS"
    
      52  export CGO_LDFLAGS="$LDFLAGS"
    
      53}
    
      54
    
      55prepare() {
    
      56  cd "herakleo-$pkgver"
    
      57  _goenv
    
      58  (cd wails && go mod download)
    
      59  (cd frontend && bun install --frozen-lockfile)
    
      60}
    
      61
    
      62build() {
    
      63  cd "herakleo-$pkgver"
    
      64  _goenv
    
      65  # Wails v3 needs no CLI: build the UI, then a plain cgo build that embeds it.
    
      66  (cd frontend && bun run build:wails)
    
      67  (cd wails && go build -tags production -ldflags '-s -w' -o build/bin/herakleo .)
    
      68}
    
      69
    
      70package() {
    
      71  cd "herakleo-$pkgver"
    
      72  install -Dm755 wails/build/bin/herakleo "$pkgdir/usr/bin/herakleo"
    
      73  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      74  install -Dm644 packaging/linux/me.crstian.Herakleo.desktop -t "$pkgdir/usr/share/applications"
    
      75  install -Dm644 packaging/linux/me.crstian.Herakleo.metainfo.xml -t "$pkgdir/usr/share/metainfo"
    
      76  local size
    
      77  for size in 128 256 512; do
    
      78    install -Dm644 "packaging/linux/icons/$size.png" \
    
      79      "$pkgdir/usr/share/icons/hicolor/${size}x${size}/apps/me.crstian.Herakleo.png"
    
      80  done
    
      81}
    
      82

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-28 21:50:44	Low	1
2026-10-28 19:50:31	Low	1