hottyterm-bin
LOW
maintainer AnatolyRugalev
0 votes
scanned 2026-10-07 14:05:47.471701
Why flagged
Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.
Triggered rules
Low
Few votes, recently uploaded
zero_votes_recent
Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.
PKGBUILD
1
# Maintainer: Anatoly Rugalev <anatoly.rugalev@gmail.com>
2
#
3
# Rendered by hottyterm's packaging/aur/publish.sh from packaging/aur/PKGBUILD
4
# in github.com/neuroplastio/hottyterm; change it there.
5
#
6
# The Linux build of a hottyterm release, as it is, in /usr/lib/hottyterm: it
7
# finds its library and its resources (share/ghostty) beside its binary. What
8
# the desktop looks for by hottyterm's application id goes where it looks: the
9
# command, the desktop entry, the D-Bus and systemd services, the icons and
10
# the metainfo. What still names Ghostty (completions, man pages, terminfo)
11
# stays in /usr/lib/hottyterm, so an installed Ghostty keeps its own.
12
#
13
# pkgver is the release's day, then its commit as r<count>.<short>, so two
14
# releases of one day sort in the order they were made.
15
pkgname=hottyterm-bin
16
_pkgname=hottyterm
17
pkgver=26.10.07.r43.c466c76
18
pkgrel=1
19
_release=26.10.07-dev.c466c76
20
pkgdesc="A fork of Ghostty with native HOTTY (HTML over the TTY)"
21
arch=('x86_64')
22
url="https://github.com/neuroplastio/hottyterm"
23
license=('MIT')
24
depends=('fontconfig' 'glib2' 'glibc' 'gtk4' 'gtk4-layer-shell' 'hicolor-icon-theme'
25
'libadwaita' 'libgcc' 'libglvnd' 'libx11' 'wayland')
26
provides=("$_pkgname")
27
conflicts=("$_pkgname")
28
# Built and stripped by hottyterm's CI: nothing for makepkg to strip, and no
29
# debug package.
30
options=('!strip' '!debug')
31
source_x86_64=("hottyterm-${_release}-linux-${CARCH}.tar.gz::https://github.com/neuroplastio/hottyterm/releases/download/${_release}/hottyterm-${_release}-linux-${CARCH}.tar.gz")
32
sha256sums_x86_64=('d731547759a5b566e1ac46de2e4f3cb5b83aa1a6b7cdf7c77a9c1e77fd9636e7')
33
34
package() {
35
local id=io.github.neuroplastio.hottyterm f
36
local home="$pkgdir/usr/lib/$_pkgname"
37
38
install -d "$pkgdir/usr/lib"
39
cp -a "$_pkgname" "$home"
40
# Ghostty's VT library and its headers, which hottyterm does not use, and
41
# its Nautilus extension, which Nautilus would never find here.
42
rm -rf "$home/include" "$home/lib/libghostty-vt."* "$home/share/pkgconfig" \
43
"$home/share/nautilus-python"
44
45
install -d "$pkgdir/usr/bin"
46
ln -s "/usr/lib/$_pkgname/bin/$_pkgname" "$pkgdir/usr/bin/$_pkgname"
47
48
# The build wrote the path it was built at into these; installed, the
49
# command is /usr/bin/hottyterm.
50
for f in "applications/$id.desktop" "dbus-1/services/$id.service" "kio/servicemenus/$id.desktop"; do
51
install -d "$pkgdir/usr/share/${f%/*}"
52
sed -E "s#/[^ =]*/bin/$_pkgname#/usr/bin/$_pkgname#g" "$_pkgname/share/$f" > "$pkgdir/usr/share/$f"
53
done
54
install -d "$pkgdir/usr/lib/systemd/user"
55
sed -E "s#/[^ =]*/bin/$_pkgname#/usr/bin/$_pkgname#g" "$_pkgname/share/systemd/user/app-$id.service" \
56
> "$pkgdir/usr/lib/systemd/user/app-$id.service"
57
install -Dm644 "$_pkgname/share/metainfo/$id.metainfo.xml" "$pkgdir/usr/share/metainfo/$id.metainfo.xml"
58
cp -a "$_pkgname/share/icons" "$pkgdir/usr/share/icons"
59
60
install -Dm644 "$_pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
61
install -Dm644 "$_pkgname/THIRD-PARTY-NOTICES.txt" "$pkgdir/usr/share/licenses/$pkgname/THIRD-PARTY-NOTICES.txt"
62
}
63
Scan history
| Scanned at (UTC) | Severity | Rules |
|---|---|---|
| 2026-10-07 14:05:47 | Low | 1 |