ik-llama.cpp-cuda-opt-git
LOW
maintainer ItachiSan
0 votes
scanned 2026-09-08 15:17:32.240420
Why flagged
Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.
Triggered rules
Low
Few votes, recently uploaded
zero_votes_recent
Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.
PKGBUILD
1
# Maintainer: Giovanni Santini <giovannisantini93@yahoo.it>
2
# Maintainer: Bink
3
pkgname=ik-llama.cpp-cuda-opt-git
4
_pkgname="ik_llama.cpp"
5
pkgver=t0002.r1064.1a2a8604a
6
pkgrel=1
7
pkgdesc="Port of Facebook's LLaMA model in C/C++ (with NVIDIA CUDA optimizations) - fork by ikawrakow, installed in /opt"
8
arch=(x86_64 armv7h aarch64)
9
url='https://github.com/ikawrakow/ik_llama.cpp'
10
license=('MIT')
11
depends=(
12
cuda
13
curl
14
gcc-libs
15
glibc
16
nvidia-utils
17
openssl
18
nccl
19
gcc15-libs
20
)
21
makedepends=(
22
cmake
23
gcc15 # CUDA requires gcc15
24
git
25
ninja
26
)
27
optdepends=(
28
'ccache: greatly reduce package re-build time'
29
'rdma-core: RDMA transport for RPC backend (rebuild required)'
30
'python-numpy: needed for convert_hf_to_gguf.py'
31
'python-safetensors: needed for convert_hf_to_gguf.py'
32
'python-sentencepiece: needed for convert_hf_to_gguf.py'
33
'python-pytorch: needed for convert_hf_to_gguf.py'
34
'python-transformers: needed for convert_hf_to_gguf.py'
35
)
36
source=(
37
"git+https://github.com/ikawrakow/ik_llama.cpp.git"
38
llama.cpp.conf
39
llama.cpp.service
40
)
41
sha256sums=('SKIP'
42
'53fa70cfe40cb8a3ca432590e4f76561df0f129a31b121c9b4b34af0da7c4d87'
43
'99609872ad5deeb64ba969d6c9041f6b8534f6198f181d5b9c02deca9b7ae790')
44
45
pkgver() {
46
cd "${_pkgname}" || exit
47
printf "%s" "$(git describe --tags | sed 's/\([^-]*-\)g/r\1/;s/-/./g')"
48
}
49
50
build() {
51
# This may not be set if the user's session
52
# has not restarted on a new 'cuda' install
53
if [[ -z "${NVCC_CCBIN}" ]]; then
54
source /etc/profile
55
fi
56
57
# Grab commit ID and build number.
58
local _commit_id _build_number
59
_commit_id=$(git -C "${_pkgname}" rev-parse HEAD)
60
_build_number=$(git -C "${_pkgname}" rev-list --count HEAD)
61
62
local _cmake_options=(
63
-G Ninja
64
-B build
65
-S "${_pkgname}"
66
-DCMAKE_BUILD_TYPE=Release
67
-DCMAKE_INSTALL_PREFIX="/opt/${_pkgname}"
68
-DCMAKE_INSTALL_RPATH="/opt/${_pkgname}/lib:/usr/lib/nvidia:/usr/lib"
69
-DCMAKE_BUILD_RPATH="/opt/${_pkgname}/lib:/usr/lib/nvidia:/usr/lib"
70
-DBUILD_SHARED_LIBS=ON
71
-DLLAMA_ALL_WARNINGS=OFF
72
-DGGML_ALL_WARNINGS_3RD_PARTY=OFF
73
-DGGML_BUILD_EXAMPLES=OFF # Change to on if you want examples
74
-DLLAMA_BUILD_TESTS=OFF
75
-DLLAMA_BUILD_SERVER=ON
76
-DLLAMA_BUILD_NUMBER="${_build_number}"
77
-DLLAMA_BUILD_COMMIT="${_commit_id}"
78
-DLLAMA_OPENSSL=ON
79
-DGGML_OPENMP=ON
80
-DGGML_LTO=ON
81
-DGGML_RPC=ON
82
-DGGML_CUDA=ON
83
-DGGML_CUDA_FA_ALL_QUANTS=ON
84
-DGGML_CUDA_COMPRESSION_MODE=speed
85
-DGGML_BLAS=OFF
86
-DGGML_VULKAN=OFF
87
-Wno-author
88
)
89
90
if [[ ${aur_llamacpp_build_universal} == true ]]; then
91
echo "Building universal binary [aur_llamacpp_build_universal == true]"
92
_cmake_options+=(
93
-DGGML_BACKEND_DL=ON
94
-DGGML_NATIVE=OFF
95
-DGGML_CPU_ALL_VARIANTS=ON
96
)
97
else
98
# makepkg sets SOURCE_DATE_EPOCH, which would otherwise disable native defaults
99
_cmake_options+=(
100
-DGGML_NATIVE=ON
101
-DCMAKE_CUDA_ARCHITECTURES=native
102
)
103
fi
104
105
# Allow user-specified additional flags
106
if [[ -n "${aur_llamacpp_cmakeopts:-}" ]]; then
107
echo "Applying custom CMake options: ${aur_llamacpp_cmakeopts}"
108
# shellcheck disable=SC2206 # intentional word splitting
109
_cmake_options+=(${aur_llamacpp_cmakeopts})
110
fi
111
112
cmake "${_cmake_options[@]}"
113
cmake --build build
114
}
115
116
package() {
117
DESTDIR="${pkgdir}" cmake --install build
118
install -Dm644 "${_pkgname}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
119
install -Dm644 "llama.cpp.conf" "${pkgdir}/etc/conf.d/ik-llama.cpp-opt"
120
install -Dm644 "llama.cpp.service" "${pkgdir}/usr/lib/systemd/system/ik-llama.cpp-opt.service"
121
}
122
Scan history
| Scanned at (UTC) | Severity | Rules |
|---|---|---|
| 2026-09-08 15:17:32 | Low | 1 |