kakikotoba-git

LOW

maintainer kabeuchi-bird 0 votes scanned 2026-11-05 04:08:19.306895

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: kabeuchi_bird
    
      2pkgname=kakikotoba-git
    
      3_pkgname=kakikotoba
    
      4pkgver=r28.a631f47
    
      5pkgrel=1
    
      6pkgdesc='Vertical text editor for novel writing'
    
      7arch=('x86_64')
    
      8url='https://github.com/kabeuchi-bird/kakikotoba'
    
      9license=('MIT')
    
      10depends=('fontconfig' 'gcc-libs' 'glibc' 'hicolor-icon-theme' 'kirigami' 'qt6-base' 'qt6-declarative')
    
      11makedepends=('cargo' 'git')
    
      12# テストが読むフォント。ないとテストが何も確かめずに通る
    
      13checkdepends=('noto-fonts-cjk' 'ttf-dejavu')
    
      14optdepends=('fcitx5: vertical conversion candidates drawn in the editor'
    
      15            'noto-fonts-cjk: preferred Japanese font')
    
      16provides=("$_pkgname")
    
      17conflicts=("$_pkgname")
    
      18# LTOを有効にすると、cxxのC++側のシンボルをリンカが解決できない
    
      19options=('!lto')
    
      20source=("git+$url.git"
    
      21        'kakikotoba.desktop')
    
      22sha256sums=('SKIP'
    
      23            'fe5910f0ffbda17b3e2b326cfd5032421146b6fc7f97e0c71103064a258a2d03')
    
      24
    
      25pkgver() {
    
      26  cd "$_pkgname"
    
      27  printf 'r%s.%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
    
      28}
    
      29
    
      30prepare() {
    
      31  cd "$_pkgname"
    
      32  export RUSTUP_TOOLCHAIN=stable
    
      33  cargo fetch --locked --target "$(rustc --print host-tuple)"
    
      34}
    
      35
    
      36build() {
    
      37  cd "$_pkgname"
    
      38  export RUSTUP_TOOLCHAIN=stable
    
      39  export CARGO_TARGET_DIR=target
    
      40  cargo build --frozen --release -p kakikotoba
    
      41}
    
      42
    
      43check() {
    
      44  cd "$_pkgname"
    
      45  export RUSTUP_TOOLCHAIN=stable
    
      46  export CARGO_TARGET_DIR=target
    
      47  cargo test --frozen --workspace
    
      48}
    
      49
    
      50package() {
    
      51  install -Dm644 kakikotoba.desktop -t "$pkgdir/usr/share/applications"
    
      52  cd "$_pkgname"
    
      53  install -Dm755 target/release/kakikotoba -t "$pkgdir/usr/bin"
    
      54  install -Dm644 assets/kakikotoba.svg -t "$pkgdir/usr/share/icons/hicolor/scalable/apps"
    
      55  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
    
      56}
    
      57

Scan history

Scanned at (UTC)	Severity	Rules
2026-11-05 04:08:19	Low	1