kanshi-gtk4-git

LOW

maintainer Maxr 0 votes scanned 2026-10-29 05:51:59.620878

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Max Roder <maxroder@mailbox.org>
    
      2# Contributor: grigio <https://github.com/grigio>
    
      3
    
      4pkgname=kanshi-gtk4-git
    
      5_pkgname=kanshi-gtk4
    
      6pkgver=0.4.0.r0.g5d54ea3
    
      7pkgrel=1
    
      8pkgdesc="Arrange displays on Wayland and save the layout as a kanshi profile"
    
      9arch=('x86_64')
    
      10url="https://github.com/grigio/kanshi-gtk4"
    
      11license=('GPL-3.0-only')
    
      12depends=('cairo' 'glib2' 'glibc' 'gtk4' 'hicolor-icon-theme' 'libadwaita' 'libgcc'
    
      13         'wlr-randr')
    
      14makedepends=('git' 'cargo' 'pkgconf')
    
      15optdepends=('kanshi: persist layouts across reboot and hotplug'
    
      16            'cosmic-randr: real mirroring on COSMIC')
    
      17checkdepends=('desktop-file-utils' 'python')
    
      18provides=("$_pkgname")
    
      19conflicts=("$_pkgname")
    
      20source=("git+$url.git")
    
      21sha256sums=('SKIP')
    
      22
    
      23pkgver() {
    
      24  cd "$_pkgname"
    
      25  git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
    
      26}
    
      27
    
      28prepare() {
    
      29  cd "$_pkgname"
    
      30  export RUSTUP_TOOLCHAIN=stable
    
      31  cargo fetch --locked --target "$(rustc --print host-tuple)"
    
      32}
    
      33
    
      34build() {
    
      35  cd "$_pkgname"
    
      36  export RUSTUP_TOOLCHAIN=stable
    
      37  export CARGO_TARGET_DIR=target
    
      38  cargo build --frozen --release
    
      39}
    
      40
    
      41check() {
    
      42  cd "$_pkgname"
    
      43  export RUSTUP_TOOLCHAIN=stable
    
      44  desktop-file-validate data/io.github.kanshi_gtk4.desktop
    
      45  # watchdog_restores_when_the_app_never_confirms is racy: it reads the
    
      46  # watchdog's marker right after the outputs flip back, before the watchdog
    
      47  # has written it (src/watchdog.rs), and fails about one run in five.
    
      48  cargo test --frozen -- --skip watchdog_restores_when_the_app_never_confirms
    
      49}
    
      50
    
      51package() {
    
      52  cd "$_pkgname"
    
      53  install -Dm755 target/release/kanshi-gtk4 "$pkgdir/usr/bin/kanshi-gtk4"
    
      54  install -Dm644 data/io.github.kanshi_gtk4.desktop \
    
      55    "$pkgdir/usr/share/applications/io.github.kanshi_gtk4.desktop"
    
      56  install -Dm644 data/icons/hicolor/scalable/apps/io.github.kanshi_gtk4.svg \
    
      57    "$pkgdir/usr/share/icons/hicolor/scalable/apps/io.github.kanshi_gtk4.svg"
    
      58  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      59}
    
      60

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-29 05:51:59	Low	1