kicad-component-importer-git

LOW

maintainer lucaci32u4 0 votes scanned 2026-08-26 01:28:49.644801

View on AUR

Why flagged

The package builds from the project's own Git repository, which is normal for AUR packages; the low severity is due to few votes and recent upload, not malicious content.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Low AI review llm_review

An AI model (qwen/qwen3-235b-a22b-2507) reviewed this and agrees it is LOW (confidence 95%): The package builds from the project's own Git repository, which is normal for AUR packages; the low severity is due to few votes and recent upload, not malicious content.

PKGBUILD

      1# Maintainer: Alexandru Iercosan-Lucaci <lucaci32u4@gmail.com>
    
      2pkgname=kicad-component-importer-git
    
      3_pkgname=kicad-component-importer
    
      4pkgver=0.1.6.r2.ga3e40b5
    
      5pkgrel=1
    
      6pkgdesc="Desktop app and CLI for importing downloaded component ZIP libraries into KiCad projects"
    
      7arch=('any')
    
      8url="https://github.com/robertxdx/component-importer-for-kicad"
    
      9license=('MIT')
    
      10depends=('python' 'python-pyqt6')
    
      11makedepends=('git' 'python-build' 'python-installer' 'python-wheel' 'python-setuptools')
    
      12optdepends=('fzf: fuzzy ZIP picker for the CLI'
    
      13            'kicad: EDA suite the imported libraries are used with')
    
      14provides=("${_pkgname}")
    
      15conflicts=("${_pkgname}")
    
      16source=("${_pkgname}::git+https://github.com/robertxdx/component-importer-for-kicad.git")
    
      17sha256sums=('SKIP')
    
      18
    
      19pkgver() {
    
      20  cd "${srcdir}/${_pkgname}"
    
      21  git describe --long --abbrev=7 --tags 2>/dev/null |
    
      22    sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
    
      23    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
    
      24}
    
      25
    
      26build() {
    
      27  cd "${srcdir}/${_pkgname}"
    
      28  python -m build --wheel --no-isolation
    
      29}
    
      30
    
      31package() {
    
      32  cd "${srcdir}/${_pkgname}"
    
      33  python -m installer --destdir="${pkgdir}" dist/*.whl
    
      34
    
      35  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    
      36  install -Dm644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README.md"
    
      37  install -Dm644 docs/CLI.md "${pkgdir}/usr/share/doc/${pkgname}/CLI.md"
    
      38  if [ -f docs/man/kicad-importer.1 ]; then
    
      39    install -Dm644 docs/man/kicad-importer.1 \
    
      40      "${pkgdir}/usr/share/man/man1/kicad-importer.1"
    
      41  fi
    
      42
    
      43  install -Dm644 src/component_importer/gui_assets/app_icon.png \
    
      44    "${pkgdir}/usr/share/pixmaps/${_pkgname}.png"
    
      45
    
      46  install -Dm644 /dev/stdin \
    
      47    "${pkgdir}/usr/share/applications/${_pkgname}.desktop" <<'DESKTOP'
    
      48[Desktop Entry]
    
      49Type=Application
    
      50Name=KiCad Component Importer
    
      51Comment=Import component ZIP files into KiCad symbol and footprint libraries
    
      52Exec=component-importer-for-kicad
    
      53Icon=kicad-component-importer
    
      54Categories=Development;Electronics;
    
      55Terminal=false
    
      56StartupNotify=true
    
      57DESKTOP
    
      58}
    
      59

Scan history

Scanned at (UTC)	Severity	Rules
2026-08-26 01:28:49	Low	2