kiota

LOW

maintainer agony4001 0 votes scanned 2026-11-05 12:09:09.970845

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: agony <27015 at riseup dot net>
    
      2
    
      3pkgname=kiota
    
      4pkgver=1.38.0
    
      5pkgrel=1
    
      6pkgdesc='OpenAPI based HTTP client code generator'
    
      7arch=('x86_64')
    
      8url='https://github.com/microsoft/kiota'
    
      9license=('MIT')
    
      10depends=('dotnet-runtime-10.0' 'glibc' 'libgcc' 'libstdc++')
    
      11makedepends=('dotnet-sdk-10.0')
    
      12options=('!debug')
    
      13install=kiota.install
    
      14source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz")
    
      15sha256sums=('b69b1981d4405224a5dbe02c21f43be9c753e5dd99c1f499b8af269a24fc1488')
    
      16
    
      17_project=src/kiota/kiota.csproj
    
      18
    
      19_dotnet_env() {
    
      20  export HOME="${srcdir}/home"
    
      21  export DOTNET_CLI_TELEMETRY_OPTOUT=1
    
      22  export DOTNET_GENERATE_ASPNET_CERTIFICATE=false
    
      23  export DOTNET_NOLOGO=1
    
      24  export DOTNET_SKIP_WORKLOAD_INTEGRITY_CHECK=1
    
      25  mkdir -p "${HOME}"
    
      26}
    
      27
    
      28prepare() {
    
      29  cd "${pkgname}-${pkgver}"
    
      30  _dotnet_env
    
      31  # global.json pins SDK 10.0.402, newer than the SDK in extra
    
      32  rm global.json
    
      33  dotnet restore "${_project}" --disable-build-servers
    
      34}
    
      35
    
      36build() {
    
      37  cd "${pkgname}-${pkgver}"
    
      38  _dotnet_env
    
      39  dotnet publish "${_project}" \
    
      40    --no-restore \
    
      41    --disable-build-servers \
    
      42    --configuration Release \
    
      43    --framework net10.0 \
    
      44    --self-contained false \
    
      45    --output "${srcdir}/publish" \
    
      46    -p:EnableSourceControlManagerQueries=false \
    
      47    -p:DebugType=none \
    
      48    -p:DebugSymbols=false
    
      49}
    
      50
    
      51check() {
    
      52  _dotnet_env
    
      53  KIOTA_OFFLINE_ENABLED=true KIOTA_CLI_TELEMETRY_OPTOUT=1 \
    
      54    "${srcdir}/publish/kiota" info -l Java | grep -q 'maturity level'
    
      55}
    
      56
    
      57package() {
    
      58  install -d "${pkgdir}/usr/lib/${pkgname}" "${pkgdir}/usr/bin"
    
      59  cp -a "${srcdir}/publish/." "${pkgdir}/usr/lib/${pkgname}/"
    
      60  ln -s "/usr/lib/${pkgname}/kiota" "${pkgdir}/usr/bin/kiota"
    
      61  install -Dm644 "${pkgname}-${pkgver}/LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
    
      62}
    
      63

Scan history

Scanned at (UTC)	Severity	Rules
2026-11-05 12:09:09	Low	1