kmux-workspaces-git

LOW

maintainer egor3f 1 votes scanned 2026-10-06 08:02:16.298752

View on AUR

Why flagged

The package builds from a git source on GitHub from a project-associated repository; the low severity is due to few votes and recent upload, but the source is legitimate and the build process is standard.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Low AI review llm_review

An AI model (qwen/qwen3-235b-a22b-2507) reviewed this and agrees it is LOW (confidence 95%): The package builds from a git source on GitHub from a project-associated repository; the low severity is due to few votes and recent upload, but the source is legitimate and the build process is standard.

PKGBUILD

      1# SPDX-FileCopyrightText: 2026 Kmux contributors
    
      2# SPDX-License-Identifier: CC0-1.0
    
      3# Maintainer: egor3f <ef@efprojects.com>
    
      4# Contributor: vityas-off <15840124+vityas-off@users.noreply.github.com>
    
      5
    
      6pkgname=kmux-workspaces-git
    
      7pkgver=0.1.0alpha.1.r10601.ge625bb1
    
      8pkgrel=1
    
      9pkgdesc='Project-workspace terminal based on KDE Konsole, inspired by cmux (development version)'
    
      10arch=(x86_64)
    
      11url='https://github.com/vityas-off/kmux'
    
      12license=(GPL-2.0-or-later
    
      13         LGPL-2.0-or-later)
    
      14# Keep depends, makedepends, and the CMake options in sync with the
    
      15# kmux-workspaces package.
    
      16depends=(glibc
    
      17         hicolor-icon-theme
    
      18         icu
    
      19         kbookmarks
    
      20         kcolorscheme
    
      21         kconfig
    
      22         kconfigwidgets
    
      23         kcoreaddons
    
      24         kcrash
    
      25         kdbusaddons
    
      26         kglobalaccel
    
      27         kguiaddons
    
      28         ki18n
    
      29         kiconthemes
    
      30         kio
    
      31         knewstuff
    
      32         knotifications
    
      33         knotifyconfig
    
      34         kparts
    
      35         kpty
    
      36         kservice
    
      37         ktextwidgets
    
      38         kwidgetsaddons
    
      39         kwindowsystem
    
      40         kxmlgui
    
      41         libssh
    
      42         libstdc++
    
      43         libxkbcommon
    
      44         qt6-base
    
      45         qt6-multimedia
    
      46         sh)
    
      47makedepends=(extra-cmake-modules
    
      48             git
    
      49             ninja)
    
      50optdepends=('keditbookmarks: to manage bookmarks')
    
      51provides=(kmux-workspaces)
    
      52# The unrelated kmux-git package (a tmux client based on Konsole) provides
    
      53# "kmux" and installs the same /usr/bin/kmux path.
    
      54conflicts=(kmux
    
      55           kmux-workspaces)
    
      56source=("kmux::git+$url.git")
    
      57sha256sums=('SKIP')
    
      58
    
      59# The repository carries the inherited Konsole tags (v24.01.90 and others), so
    
      60# git describe would report Konsole versions. Use the Kmux version from
    
      61# CMakeLists.txt and the commit count, which only grows.
    
      62pkgver() {
    
      63  cd kmux
    
      64  local version prerelease
    
      65  version=$(sed -nE 's/^set\(KMUX_VERSION_(MAJOR|MINOR|PATCH) "([0-9]+)"\)$/\2/p' CMakeLists.txt | paste -sd.)
    
      66  prerelease=$(sed -nE 's/^set\(KMUX_VERSION_PRERELEASE "([^"]*)"\)$/\1/p' CMakeLists.txt)
    
      67  printf '%s%s.r%s.g%s' "$version" "${prerelease//-/}" \
    
      68    "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
    
      69}
    
      70
    
      71build() {
    
      72  cmake -B build -S kmux -G Ninja \
    
      73    -DCMAKE_BUILD_TYPE=None \
    
      74    -DCMAKE_INSTALL_PREFIX=/usr \
    
      75    -DBUILD_TESTING=OFF \
    
      76    -DWITH_KAPSULE=OFF \
    
      77    -DWITH_LIBSSH=ON \
    
      78    -Wno-dev
    
      79  cmake --build build
    
      80}
    
      81
    
      82package() {
    
      83  DESTDIR="$pkgdir" cmake --install build
    
      84}
    
      85

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-06 08:02:16	Low	2