krakend

LOW

maintainer agony4001 0 votes scanned 2026-11-05 12:09:09.970845

View on AUR

Why flagged

Package builds from official source code on GitHub, uses standard Go build process, and installs configuration files and binaries as expected; the only concern is default telemetry to usage.krakend.io, which is disclosed in the install script but not inherently malicious.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Low AI review llm_review

An AI model (qwen/qwen3-235b-a22b-2507) reviewed this and agrees it is LOW (confidence 95%): Package builds from official source code on GitHub, uses standard Go build process, and installs configuration files and binaries as expected; the only concern is default telemetry to usage.krakend.io, which is disclosed in the install script but not inherently malicious.

PKGBUILD

      1# Maintainer: agony <27015 at riseup dot net>
    
      2
    
      3pkgname=krakend
    
      4pkgver=3.0.3
    
      5pkgrel=1
    
      6pkgdesc='High-performance, stateless, declarative API gateway'
    
      7arch=('x86_64' 'aarch64')
    
      8url='https://github.com/krakend/krakend-ce'
    
      9license=('Apache-2.0')
    
      10depends=('glibc')
    
      11makedepends=('go')
    
      12backup=('etc/krakend/krakend.json')
    
      13install=krakend.install
    
      14source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz"
    
      15        'krakend.sysusers')
    
      16sha256sums=('ee444b0267929e56d4aa561bd7a442c90427550438c4b348e43f94ad37ec01ff'
    
      17            '6710405313f2e37386f5299581058a0ba5e14bd800262a04759c0faa98e48c08')
    
      18
    
      19prepare() {
    
      20  cd "krakend-ce-${pkgver}"
    
      21  export GOPATH="${srcdir}/gopath"
    
      22  go mod download -x -modcacherw
    
      23}
    
      24
    
      25build() {
    
      26  cd "krakend-ce-${pkgver}"
    
      27  export GOPATH="${srcdir}/gopath"
    
      28  export CGO_CPPFLAGS="${CPPFLAGS}"
    
      29  export CGO_CFLAGS="${CFLAGS}"
    
      30  export CGO_CXXFLAGS="${CXXFLAGS}"
    
      31  export CGO_LDFLAGS="${LDFLAGS}"
    
      32  export GOFLAGS='-buildmode=pie -trimpath -buildvcs=false -mod=readonly -modcacherw'
    
      33  local _lura='github.com/luraproject/lura/v3/core'
    
      34  go build -v -ldflags="-linkmode=external -X ${_lura}.KrakendVersion=${pkgver} -X ${_lura}.GlibcVersion=$(sh find_glibc.sh)" \
    
      35    -o krakend ./cmd/krakend-ce
    
      36}
    
      37
    
      38check() {
    
      39  cd "krakend-ce-${pkgver}"
    
      40  # The integration tests bind ports 8080 and 8081 and fetch a feed from showrss.info
    
      41  ./krakend check -c krakend.json
    
      42}
    
      43
    
      44package() {
    
      45  cd "krakend-ce-${pkgver}"
    
      46  install -Dm755 krakend -t "${pkgdir}/usr/bin"
    
      47  install -Dm644 krakend.json -t "${pkgdir}/etc/krakend"
    
      48  install -Dm644 builder/files/krakend.service -t "${pkgdir}/usr/lib/systemd/system"
    
      49  install -Dm644 "${srcdir}/krakend.sysusers" "${pkgdir}/usr/lib/sysusers.d/krakend.conf"
    
      50}
    
      51

Scan history

Scanned at (UTC)	Severity	Rules
2026-11-05 12:09:09	Low	2