laneway

LOW

maintainer koen_hendriks 0 votes scanned 2026-09-28 19:21:21.991743

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Koen Hendriks <aur@koenhendriks.nl>
    
      2
    
      3# publish.sh stamps pkgver from the tag being released and fills in b2sums;
    
      4# bump pkgrel here when the recipe changes without a new release.
    
      5pkgname=laneway
    
      6pkgver=0.1.0
    
      7pkgrel=1
    
      8pkgdesc='A terminal board for Jira'
    
      9arch=('x86_64' 'aarch64')
    
      10url='https://github.com/cornedor/laneway'
    
      11license=('MIT')
    
      12depends=('glibc')
    
      13makedepends=('go')
    
      14options=('!lto')
    
      15source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
    
      16b2sums=('df53412b794ce67670dd968aca0ec5501796d122b0cbf49fee4d175cead20161d86c658715828d15430f5f07509a068677c122afde9963553a64a3730398d434')
    
      17
    
      18prepare() {
    
      19	cd "$pkgname-$pkgver"
    
      20	go mod download -modcacherw
    
      21}
    
      22
    
      23build() {
    
      24	cd "$pkgname-$pkgver"
    
      25	export CGO_CPPFLAGS="$CPPFLAGS"
    
      26	export CGO_CFLAGS="$CFLAGS"
    
      27	export CGO_CXXFLAGS="$CXXFLAGS"
    
      28	export CGO_LDFLAGS="$LDFLAGS"
    
      29	export GOFLAGS='-buildmode=pie -trimpath -mod=readonly -modcacherw'
    
      30	go build -ldflags "-linkmode=external -X main.version=$pkgver" -o build/laneway .
    
      31	local shell
    
      32	for shell in bash zsh fish; do
    
      33		./build/laneway completion "$shell" >"build/laneway.$shell"
    
      34	done
    
      35}
    
      36
    
      37check() {
    
      38	cd "$pkgname-$pkgver"
    
      39	go test -mod=readonly -modcacherw ./...
    
      40}
    
      41
    
      42package() {
    
      43	cd "$pkgname-$pkgver"
    
      44	install -Dm755 build/laneway "$pkgdir/usr/bin/laneway"
    
      45	install -Dm644 build/laneway.bash "$pkgdir/usr/share/bash-completion/completions/laneway"
    
      46	install -Dm644 build/laneway.zsh "$pkgdir/usr/share/zsh/site-functions/_laneway"
    
      47	install -Dm644 build/laneway.fish "$pkgdir/usr/share/fish/vendor_completions.d/laneway.fish"
    
      48	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      49	install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
    
      50	install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname" docs/*.md
    
      51	install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname/guide" docs/guide/*.md
    
      52}
    
      53

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-28 19:21:21	Low	1