laneway-git

LOW

maintainer koen_hendriks 0 votes scanned 2026-09-28 19:21:21.991743

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Koen Hendriks <aur@koenhendriks.nl>
    
      2
    
      3pkgname=laneway-git
    
      4pkgver=r489.2f2af5d
    
      5pkgrel=1
    
      6pkgdesc='A terminal board for Jira'
    
      7arch=('x86_64' 'aarch64')
    
      8url='https://github.com/cornedor/laneway'
    
      9license=('MIT')
    
      10depends=('glibc')
    
      11makedepends=('git' 'go')
    
      12provides=('laneway')
    
      13conflicts=('laneway')
    
      14options=('!lto')
    
      15source=("$pkgname::git+$url.git")
    
      16b2sums=('SKIP')
    
      17
    
      18pkgver() {
    
      19	cd "$pkgname"
    
      20	local tag
    
      21	if tag=$(git describe --long --tags 2>/dev/null); then
    
      22		printf '%s' "$tag" | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
    
      23	else
    
      24		printf 'r%s.%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
    
      25	fi
    
      26}
    
      27
    
      28prepare() {
    
      29	cd "$pkgname"
    
      30	go mod download -modcacherw
    
      31}
    
      32
    
      33build() {
    
      34	cd "$pkgname"
    
      35	export CGO_CPPFLAGS="$CPPFLAGS"
    
      36	export CGO_CFLAGS="$CFLAGS"
    
      37	export CGO_CXXFLAGS="$CXXFLAGS"
    
      38	export CGO_LDFLAGS="$LDFLAGS"
    
      39	export GOFLAGS='-buildmode=pie -trimpath -mod=readonly -modcacherw'
    
      40	go build -ldflags "-linkmode=external -X main.version=$pkgver" -o build/laneway .
    
      41	local shell
    
      42	for shell in bash zsh fish; do
    
      43		./build/laneway completion "$shell" >"build/laneway.$shell"
    
      44	done
    
      45}
    
      46
    
      47check() {
    
      48	cd "$pkgname"
    
      49	go test -mod=readonly -modcacherw ./...
    
      50}
    
      51
    
      52package() {
    
      53	cd "$pkgname"
    
      54	install -Dm755 build/laneway "$pkgdir/usr/bin/laneway"
    
      55	install -Dm644 build/laneway.bash "$pkgdir/usr/share/bash-completion/completions/laneway"
    
      56	install -Dm644 build/laneway.zsh "$pkgdir/usr/share/zsh/site-functions/_laneway"
    
      57	install -Dm644 build/laneway.fish "$pkgdir/usr/share/fish/vendor_completions.d/laneway.fish"
    
      58	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      59	install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
    
      60	install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname" docs/*.md
    
      61	install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname/guide" docs/guide/*.md
    
      62}
    
      63

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-28 19:21:21	Low	1
2026-09-28 17:21:20	Low	1