lib32-lz4

LOW

maintainer orphaned 0 votes scanned 2026-08-23 13:20:29.873780

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
    
      2# Contributor: Sébastien Luttringer
    
      3
    
      4_pkgname=lz4
    
      5pkgname=lib32-lz4
    
      6pkgver=1.10.0
    
      7pkgrel=3
    
      8pkgdesc='Extremely fast compression algorithm (32-bit)'
    
      9arch=('x86_64')
    
      10url='https://lz4.github.io/lz4/'
    
      11license=('GPL-2.0-or-later')
    
      12makedepends=('git')
    
      13checkdepends=('diffutils')
    
      14depends=('lz4' 'lib32-glibc')
    
      15provides=('liblz4.so')
    
      16source=("git+https://github.com/lz4/lz4.git#tag=v$pkgver")
    
      17sha256sums=('487f9bc24fdaf589e2f4bb23dd98b1f21a71b643db09251145616587c9468555')
    
      18
    
      19build() {
    
      20  cd ${_pkgname}
    
      21  export CC="gcc -m32"
    
      22  export CXX="g++ -m32"
    
      23  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
    
      24  # do not use the main makefile, it calls sub make with -e
    
      25  # exported CLFAGS by makepkg break the version. see FS#50071
    
      26  make -C lib PREFIX=/usr
    
      27  make -C programs PREFIX=/usr lz4 lz4c
    
      28}
    
      29
    
      30check() {
    
      31  rm -f passwd.lz4
    
      32  ${_pkgname}/programs/lz4 /etc/passwd passwd.lz4
    
      33  ${_pkgname}/programs/lz4 -d passwd.lz4 passwd
    
      34  diff -q /etc/passwd passwd
    
      35  rm passwd
    
      36}
    
      37
    
      38package() {
    
      39  cd ${_pkgname}
    
      40  make install \
    
      41    PREFIX=/usr \
    
      42    LIBDIR=/usr/lib32 \
    
      43    PKGCONFIGDIR=/usr/lib32/pkgconfig \
    
      44    DESTDIR="${pkgdir}"
    
      45  rm -rf "${pkgdir}"/usr/{share,include,bin}
    
      46}
    
      47
    
      48# vim: ts=2 sw=2 et:
    
      49

Scan history

Scanned at (UTC)	Severity	Rules
2026-08-23 13:20:29	Low	1